Cara Cepat Mengekspor Total Waktu yang Dihabiskan pada Janji Outlook di Setiap Kategori Warna

Jika Anda ingin membuat laporan tentang total waktu yang Anda habiskan untuk janji temu di setiap kategori warna, Anda dapat menggunakan metode yang diperkenalkan dalam artikel ini. Ini dapat membantu Anda menyelesaikannya dalam waktu cepat tanpa perlu menghitung secara manual.

Banyak pengguna terbiasa mencatat sebagian besar aktivitas mereka di kalender Outlook. Selain itu, agar lebih mudah mengelola dan membedakan aktivitas tersebut, mereka menetapkan kategori untuk setiap aktivitas. Dalam hal ini, beberapa pengguna ingin membuat laporan yang menunjukkan total waktu yang dihabiskan untuk item kalender di setiap kategori warna. Tidak diragukan lagi, menghitung dan memasukkan data secara manual sangat merepotkan. Oleh karena itu, di sini kami akan membagikan cara yang dapat menyelesaikan tugas ini hanya dengan satu klik.

Ekspor Total Waktu yang Dihabiskan untuk Janji Temu di Setiap Kategori Warna

1. Pertama-tama, luncurkan aplikasi Outlook Anda.
2. Kemudian, setelah memasuki jendela Outlook, Anda dapat menekan tombol "Alt + F11".
3. Selanjutnya, Anda akan mendapatkan akses ke jendela "Microsoft Visual Basic for Applications".
4. Selanjutnya, Anda perlu mengaktifkan “Microsoft Excel Object Library”. Anda dapat mengklik “Tools” > “Reference” untuk melakukannya.
5. Kemudian, Anda harus mencari dan membuka modul yang tidak digunakan.
6. Setelah itu, Anda perlu menyalin kode VBA berikut ke dalam modul ini.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Terakhir, Anda dapat memicu makro ini, tidak peduli dengan mengklik ikon "Jalankan" di toolbar atau menekan tombol "F5".
8. Kemudian, Anda akan diminta untuk memilih kalender tertentu.
9. Setelah Anda memilih dan menekan "OK", makro akan terus berjalan. Setelah selesai, akan ada file Excel baru yang ditampilkan di background.
10. Anda dapat mengaksesnya. Ini akan terlihat seperti tangkapan layar berikut:

Awasi Potensi Ancaman di Sekitar Outlook Anda

Pengguna Outlook harus berhati-hati terhadap semua potensi risiko, termasuk lampiran email yang tidak dikenal, tautan yang disematkan, dan kesalahan manusia. Jika tidak, Outlook Anda bisa rusak kapan saja. Selain itu, membuat cadangan data Outlook secara teratur dan menyimpan alat perbaikan khusus adalah hal yang perlu. DataNumen Outlook Repair adalah salah satu alat perbaikan yang paling direkomendasikan. Alat ini dapat perbaiki Outlook masalah dalam sekejap.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com