Cara Cepat Mengekspor Jumlah Total Item di Setiap Folder Outlook ke Excel

Jika Anda ingin mendapatkan laporan tentang jumlah item di setiap folder Outlook, Anda dapat menggunakan metode yang diperkenalkan di artikel ini. Ini akan dengan cepat melakukan penghitungan dan mengekspor hasilnya ke dalam file Excel.

Di artikel saya sebelumnya - “Cara Cepat Mendapatkan Jumlah Total Item dalam Folder dan Semua Subfoldernya melalui Outlook VBA”, Anda dapat mempelajari metode menggunakan VBA untuk menghitung jumlah item dalam folder. Namun, dengan demikian, jika Anda ingin menghitung item di semua folder, Anda harus memilih setiap folder dan menjalankan makro satu per satu. Agak membosankan. Oleh karena itu, kami akan mengajari Anda metode lain, yang akan mengekspor hitungan ke file Excel.

Ekspor Jumlah Total Item di Setiap Folder Outlook ke Excel

1. Pertama-tama, luncurkan program Outlook Anda.
2. Kemudian tekan tombol "Alt + F11" di jendela utama Outlook.
3. Selanjutnya Anda akan masuk ke jendela "Microsoft Visual Basic for Applications", di mana Anda perlu membuka modul yang tidak digunakan.
4. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul ini.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Setelah itu, Anda perlu mengubah tingkat keamanan makro Outlook Anda ke rendah.
6. Kemudian Anda dapat kembali ke makro yang baru ditambahkan dan menekan tombol F5 untuk menjalankan makro ini.
7. Selanjutnya Anda perlu memilih file PST sumber dan tekan "OK".
8. Setelah makro selesai, Anda bisa masuk ke folder lokal yang telah ditentukan untuk menemukan file Excel baru, yang akan terlihat seperti gambar layar berikut:

Selesaikan Kesalahan PST yang Mengganggu

Mungkin Anda telah menemukan berbagai masalah selama menggunakan Outlook. Untuk mengatasi masalah kecil, Anda cukup menggunakan alat perbaikan kotak masuk. Namun demikian, jika masalahnya sangat serius sehingga melampaui apa yang dapat dilakukan alat bawaan, Anda harus menggunakan alat yang lebih kuat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaikan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com