Cara Cepat Mengekspor Folder Outlook dengan Semua Subfolder & Item ke Folder Windows

Terkadang, Anda mungkin ingin mengekspor sekaligus folder Outlook dengan semua subfolder dan item ke folder Windows. Artikel ini akan mengajari Anda metode yang menerapkan Outlook VBA.

Saat Anda ingin mengekspor folder Outlook ke drive lokal dengan semua item dalam struktur folder yang sama, jika Anda memilih untuk menyimpan dan mengekspor secara manual, itu akan memakan banyak waktu. Jadi, mengapa Anda tidak menggunakan cara lain, seperti alat ekspor atau kode VBA? Di sini kami akan mengungkap sepotong kode VBA kepada Anda. Ini akan memungkinkan Anda untuk mencapainya seperti angin sepoi-sepoi.

Ekspor Semua Subfolder & Item di Folder Outlook ke Folder Windows

1. Pertama-tama, jalankan program Outlook Anda.
2. Kemudian di jendela Outlook utama, tekan pintasan tombol "Alt + F11".
3. Selanjutnya, jendela "Microsoft Visual Basic for Applications" akan muncul.
4. Selanjutnya Anda perlu membuka modul kosong dan menyalin kode VBA berikut ke dalamnya.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Setelah itu, Anda perlu memastikan bahwa Outlook Anda mengizinkan makro di pengaturan makro.
6. Akhirnya, Anda bisa mencobanya.

• Pertama, kembali ke jendela makro baru.
• Selanjutnya klik ke subrutin "ExportFolderWithAllItems".
• Kemudian tekan tombol F5 untuk menjalankan makro ini.
• Setelah itu, Anda perlu memilih folder tertentu.
• Terakhir, ketika Anda mendapatkan pesan yang mengatakan "Selesai", Anda dapat mengakses folder lokal yang telah ditentukan sebelumnya. Anda akan menemukan semua item telah disimpan dalam struktur folder yang sama.

Mencegah Kehilangan Data dari Kerusakan Outlook

Mungkin Anda pernah mengalami banyak crash pada Outlook. Sebagian besar waktu, setelah restart, Outlook akan dapat berfungsi normal. Namun, ada juga kemungkinan file PST kita rusak. Pada saat itu, Anda akan berusaha sebaik mungkin untuk memulihkan data PST Anda, misalnya dengan menggunakan alat yang berpengalaman seperti... DataNumen Outlook Repair. Itu bisa perbaiki Outlook kesalahan dan mengekstrak data dari file PST yang disusupi tanpa kesulitan.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server memperbaiki dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com