Cara Cepat Mengekspor Rincian Semua Anggota di Grup Kontak Outlook ke Excel

Secara default, Anda hanya dapat melihat nama anggota dan alamat email di grup kontak. Jika Anda ingin mendapatkan detail anggota lainnya, Anda dapat menggunakan cara yang diperkenalkan di artikel ini.

Saat Anda mengklik dua kali grup kontak untuk membukanya, di jendelanya, Anda hanya dapat melihat nama dan alamat email anggota grup. Anda tidak bisa mendapatkan detail anggota lainnya, seperti perusahaan, jabatan, nomor telepon atau alamat bisnis, dll. Secara umum, untuk mendapatkan detail ini, Anda harus mencari kontak yang sesuai dengan anggota di folder Kontak Anda secara manual. Itu terlalu merepotkan. Di sini kami akan menunjukkan kepada Anda sepotong kode VBA, yang dapat dengan cepat mengekspor detail ini ke buku kerja Excel.

Ekspor Detail Semua Anggota dalam Grup Kontak ke Excel

1. Pertama-tama, buka aplikasi Outlook Anda.
2. Kemudian Anda harus menekan pintasan tombol "Alt + F11" di jendela utama Outlook.
3. Selanjutnya di jendela baru "Microsoft Visual Basic for Applications", Anda perlu membuka modul yang tidak digunakan atau langsung memasukkan modul baru.
4. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul ini.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Setelah itu, untuk pemeriksaan yang nyaman, Anda dapat menambahkan proyek VBA baru ke Bilah Alat Akses Cepat atau pita.
6. Kemudian setel tingkat keamanan makro Outlook Anda ke rendah.
7. Akhirnya, Anda bisa mencobanya.

• Pertama, pilih grup kontak.
• Lalu tekan tombol makro di pita atau Bilah Alat Akses Cepat.
• Makro akan segera dijalankan.
• Setelah selesai, Anda akan mendapatkan prompt "Selesai!"
• Setelah itu, Anda bisa masuk ke folder lokal tujuan yang sudah ditentukan sebelumnya, di mana Anda bisa menemukan file Excel baru.
• Buka, Anda akan melihat detail kontak anggota grup seperti tangkapan layar berikut:

Jangan Panik Menghadapi Masalah Outlook

Tidak ada yang mau menerima masalah Outlook apa pun, tidak peduli pesan kesalahan sembulan atau Outlook rusak file data. Oleh karena itu, pengguna akan cenderung panik saat menemukan masalah Outlook. Jika Anda ingin tetap tenang dalam hal itu, Anda harus memiliki dua kebutuhan. Salah satunya adalah cadangan data Outlook saat ini. Yang lainnya adalah perangkat lunak perbaikan Outlook yang kuat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com