Cara Cepat Mengecualikan Penerima "CC" Asli saat Menggunakan "Balas Semua" di Outlook

Saat menggunakan "Balas Semua", email yang menanggapi juga akan menyertakan penerima "CC" dari email asli di bidang "CC". Namun, jika Anda ingin mengecualikan jenis penerima ini, Anda dapat menggunakan metode yang diperkenalkan di artikel ini.

Terkadang, Anda ingin membalas email ke pengirim asli dan penerima "Kepada". Dalam skenario ini, Anda pasti akan berpikir untuk menggunakan opsi "Balas Semua". Namun, dengan cara ini, jika email asli juga memiliki penerima “CC”, email “Balas Semua” akan otomatis menyalin penerima “CC” ke kolom “CC”. Jika Anda tidak ingin membalasnya, Anda harus menghapusnya secara manual, yang agak merepotkan. Sekarang, berikut ini, kami akan mengajari Anda cara membiarkan Outlook menyelesaikannya secara otomatis sesuai kebutuhan Anda.

Mengecualikan Penerima “CC” Asli dengan Cepat saat Menggunakan “Balas Semua”

1. Sebagai langkah awal, buka Outlook.
2. Kemudian, akses editor VBA dengan membaca artikel sebelumnya – “Cara Menjalankan Kode VBA di Outlook Anda".
3. Selanjutnya, salin kode VBA berikut ke dalam proyek "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Selanjutnya, mulai ulang Outlook Anda untuk mengaktifkan proyek baru ini.
5. Sejak itu, setiap kali Anda menekan tombol "Balas Semua", Anda akan mendapatkan prompt, seperti yang ditunjukkan pada gambar berikut, menanyakan apakah Anda ingin mengecualikan penerima CC asli.
6. Jika Anda memilih "Ya", Outlook akan otomatis menghapus penerima di bidang "CC".

Tetap Persiapkan dengan Baik untuk Kerusakan Outlook

Seperti yang kita ketahui, tidak ada yang bisa 100% memastikan bahwa mereka kebal terhadap kerusakan Outlook. Oleh karena itu, sangat penting bagi semua pengguna Outlook reguler untuk mengambil banyak tindakan pencegahan. Pertama-tama, salah satu yang paling penting adalah menjaga cadangan data Outlook yang konsisten dan selalu diperbarui. Kemudian, perlu mempelajari cara menggunakan alat perbaikan kotak masuk. Terakhir, namun tidak kalah penting, bijaksana dan disarankan untuk memiliki seorang ahli yang berpengalaman. Perbaikan Outlook alat di sekitarnya, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com