Cara Mengatur Waktu Pengingat Default Berbeda untuk Berbagai Jenis Item yang Ditandai di Outlook Anda

Secara default, Outlook akan secara otomatis menggunakan waktu pengingat default tugas untuk semua jenis item yang ditandai. Namun, jika Anda ingin menggunakan waktu pengingat yang berbeda untuk item yang ditandai berdasarkan jenis item, Anda dapat merujuk ke metode yang diperkenalkan dalam artikel ini.

Outlook memungkinkan Anda mengatur waktu pengingat default untuk semua item berbendera, apa pun tipe itemnya. Anda bisa pergi ke menu "File" dan klik "Options". Kemudian, di jendela "Opsi Outlook", Anda dapat melihat opsi "Waktu pengingat default" pada tab "Tugas", seperti yang ditunjukkan pada gambar layar berikut.

Meski demikian, most pengguna berharap untuk menggunakan waktu pengingat yang berbeda untuk berbagai jenis item yang ditandai, seperti "9:00" untuk email yang ditandai dan "17:30" untuk kontak yang ditandai. Sekarang, berikut ini, kita akan fokus pada contoh ini untuk memperkenalkan sebuah metode.

Tetapkan Waktu Pengingat Default Berbeda untuk Berbagai Jenis Item yang Ditandai

1. Untuk start dengan, luncurkan aplikasi Outlook.
2. Kemudian, akses editor Outlook VBA dengan referensi ke "Cara Menjalankan Kode VBA di Outlook Anda".
3. Di jendela "Microsoft Visual Basic for Applications" berikutnya, salin kode berikut ke dalam proyek "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Setelah itu restart Outlook untuk mengaktifkan makro ini.
5. Mulai sekarang, setiap kali Anda menandai email, waktu pengingat akan disetel ke "10:00" pada tanggal jatuh tempo bendera.
6. Dan saat Anda menandai kontak, waktu pengingat akan disetel ke "17:30" pada tanggal jatuh tempo bendera.

Atasi Masalah Outlook secara Fleksibel

Anda dapat menemukan semua jenis masalah di Outlook Anda. Jadi, Anda harus mempelajari beberapa langkah untuk menghadapinya terlebih dahulu. Misalnya, jika Outlook Anda sering restarts, Anda perlu memperbaiki Office atau menonaktifkan add-in pihak ketiga, dll. Atau jika Outlook PST Anda terganggu, Anda dapat mencoba alat perbaikan kotak masuk. Jika gagal, Anda dapat terus menggunakan alat eksternal yang kuat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com