Cara Cepat Membuat Grup Kontak dari Semua Kontak Outlook dengan Judul Pekerjaan Tertentu

Agar lebih mudah berkomunikasi dengan kontak dengan jabatan tertentu, Anda mungkin ingin membuat grup kontak dari kontak ini dengan cepat. Nah, dalam artikel ini, kami akan membagikan metode cepat kepada Anda.

Jika Anda sering mengirim email, tugas, atau undangan rapat ke kontak yang memiliki jabatan tertentu, akan lebih mudah jika Anda membuat grup kontak dari mereka. Secara umum, dengan cara standar, Anda harus membuat grup kontak baru terlebih dahulu, lalu menambahkan kontak ke grup sebagai anggota satu per satu. Agak merepotkan. Oleh karena itu, berikut ini, kami akan mengajari Anda cara yang jauh lebih cepat untuk mendapatkannya.

Buat Grup Kontak dari Semua Kontak dengan Judul Pekerjaan Tertentu

1. Pertama-tama, di folder Kontak, pilih kontak yang memiliki jabatan tertentu.
2. Kemudian, tekan "Alt + F11" untuk mengakses editor Outlook VBA.
3. Selanjutnya, salin kode VBA berikut ke dalam modul atau proyek kosong.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Setelah itu, pindahkan kursor ke subrutin pertama.
5. Terakhir, ketuk tombol "F5" untuk menjalankan makro ini.
6. Saat makro selesai, grup kontak baru akan ditampilkan. Ini berisi semua kontak dengan judul pekerjaan yang sama dari kontak yang dipilih di Langkah 1.

Lindungi Data Outlook Secara Efektif

Meskipun Outlook kaya fitur, namun tidak dapat menghilangkan fakta bahwa ia rentan. Jadi, jika Anda tidak ingin kehilangan data Outlook Anda yang berharga, Anda harus berusaha melindunginya. Misalnya, Anda perlu membuat cadangan untuk data Outlook secara berkala. Selain itu, jika terjangkau, disarankan untuk memiliki alat perbaikan PST mutakhir, seperti DataNumen Outlook Repair, Yang dapat memperbaiki PST data dalam sekejap.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk sql rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com