Cara Otomatis Menggunakan Warna Font Berbeda untuk Membalas dan Meneruskan Email dengan Outlook VBA

Secara default, Anda tidak dapat mengatur Outlook untuk menggunakan warna font yang berbeda secara otomatis untuk membalas dan meneruskan email. Oleh karena itu, jika Anda memiliki kebutuhan tersebut, Anda dapat membaca postingan ini untuk mempelajari pendekatan yang cerdas.

Outlook hanya mengizinkan Anda untuk menentukan font yang digunakan untuk membalas dan meneruskan email. Anda bisa pergi ke "File"> "Options". Kemudian, di "Opsi Outlook", buka tab "Mail" dan klik tombol "Alat Tulis dan Font ...". Di jendela berikutnya, Anda dapat melihat tombol "Font" di "Membalas atau meneruskan pesan". Klik itu, dan kemudian Anda dapat mengatur warna font tertentu untuk membalas dan meneruskan email.

Namun, banyak pengguna berharap menggunakan warna font yang berbeda untuk membalas atau meneruskan email. Meskipun Outlook tidak menyediakan fitur langsung apa pun untuk ini, itu masih dapat direalisasikan dengan kode VBA. Sekarang, baca terus untuk mendapatkan potongan kode VBA.

Gunakan Otomatis Warna Font Berbeda untuk Membalas dan Meneruskan Email

1. Sebagai langkah awal, luncurkan aplikasi Outlook.
2. Kemudian, picu editor VBA dengan referensi ke "Cara Menjalankan Kode VBA di Outlook Anda".
3. Selanjutnya, sesuai dengan "Cara Menambahkan Referensi Pustaka Objek di VBA“, tambahkan referensi ke “MS Word Object Library”.
4. Selanjutnya, salin kode berikut ke dalam proyek "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Setelah itu, mulai ulang Outlook untuk mengaktifkan makro ini.
6. Akhirnya, Anda bisa mencobanya.

• Pilih atau buka email.
• Kemudian, klik tombol "Balas". Dalam membalas email, Anda dapat mengetikkan beberapa kata dalam body. Warna font harus merah muda.
• Atau klik tombol "Balas Semua". Di email "membalas semua" yang baru, masukkan kata-kata dalam badan. Warna fontnya pasti hijau.
• Demikian pula, klik tombol "Maju". Dalam surat penerusan, kata-kata baru akan ditampilkan dengan warna biru.

Ambil Jalan Lain untuk Perangkat Lunak yang Andal

Jika ada Korupsi OutlookSebagian besar pengguna cenderung menggunakan perangkat lunak pemulihan Outlook. Ada banyak sekali program semacam itu yang tersedia di pasaran. Dan beberapa di antaranya bahkan gratis. Namun demikian, Anda harus berhati-hati terhadap program dari sumber yang tidak dikenal karena dapat memperburuk keadaan. Anda sebaiknya menggunakan alat yang andal dan berpengalaman, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk sql rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com