Cara Otomatis Menghapus Email Outlook dari Pengirim Tertentu setelah Hari Tertentu

Agar Outlook Anda otomatis menghapus email dari pengirim tertentu dari hari-hari tertentu, Anda dapat membaca artikel ini. Di sini kami akan menunjukkan kepada Anda langkah-langkah terperinci untuk menggunakan kode VBA untuk mendapatkannya.

Saat berhubungan dengan menghapus email secara otomatis, pertama-tama Anda mungkin memikirkan fitur "Arsip Otomatis". Namun, itu tidak dapat memfilter pengirim tertentu saat mengarsipkan email secara otomatis. Oleh karena itu, misalnya, jika Anda ingin menghapus email secara otomatis dari pengirim tertentu setelah x hari, Anda harus menggunakan cara lain, seperti yang berikut ini.

Hapus Otomatis Email dari Pengirim Tertentu setelah X Hari

1. Pada awalnya, start aplikasi Outlook Anda.
2. Kemudian, picu editor Outlook VBA menurut "Cara Menjalankan Kode VBA di Outlook Anda".
3. Selanjutnya, salin kode VBA berikut ke dalam proyek "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Setelah itu restart Outlook untuk mengaktifkan makro ini.
5. Sejak itu, setiap kali email baru dari pengirim tertentu tiba di Inbox, itu akan ditetapkan dengan waktu kedaluwarsa tertentu - hari-hari tertentu setelah diterima.
6. Kemudian, setiap kali Anda start Outlook, Outlook akan otomatis memeriksa dan menghapus email yang kedaluwarsa dari pengirim tertentu.

Pulihkan Data Outlook setelah Korupsi

Mungkin Anda mengalami berbagai kesalahan dan masalah di Outlook. Lalu, apakah Anda pernah menghadapi korupsi Outlook? Misalnya, jika Anda sering keluar dari Outlook secara tidak benar, file PST Anda cenderung rusak. Biasanya, dalam kasus seperti itu, Anda dapat memilih untuk mengambil data Outlook dari cadangan. Atau Anda bisa menggunakan alat perbaikan kotak masuk atau alat eksternal yang andal, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com