Cara Mengirim Semua Lembar Kerja dalam Satu Buku Kerja Excel sebagai Email Outlook Terpisah

Jika Anda ingin mengirim semua lembar kerja di buku kerja Excel sebagai email Outlook terpisah, Anda bisa menggunakan metode yang diperkenalkan dalam artikel ini. Ini dapat memandu Anda untuk mewujudkannya secara massal tanpa repot mengirim satu per satu.

Dalam unggahan saya sebelumnya “2 Metode Cepat untuk Mengirim Lembar Kerja Excel sebagai Email Outlook“, Anda dapat mempelajari dua cara untuk mengirim satu lembar kerja Excel sebagai email. Jika Anda ingin mengirim semua lembar kerja dalam satu buku kerja sebagai email individual, menggunakan salah satu dari dua cara yang disebutkan dalam postingan tersebut akan cukup melelahkan dan merepotkan. Oleh karena itu, di sini kami akan memperkenalkan cara lain, yang dapat mewujudkan "Pengiriman Massal" tersebut dengan cepat.

Batch Kirim Semua Lembar Kerja dalam Satu Buku Kerja Excel sebagai Email Terpisah

1. Pertama-tama, Anda harus membuka buku kerja Excel sumber.
2. Kemudian, setelah memasuki jendela Excel, Anda harus mengetuk pintasan tombol "Alt + F11".
3. Selanjutnya, jendela lain yang disebut sebagai "Microsoft Visual Basic for Applications" akan ditampilkan.
4. Di dalamnya, Anda harus membuka modul yang tidak digunakan atau memasukkan modul baru.
5. Selanjutnya, Anda dapat menyalin kode VBA berikut ke dalam modul ini.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Setelah itu, Anda dapat memicu makro ini dengan menekan tombol tombol F5 atau mengklik ikon "Jalankan" di bilah alat.
7. Sekaligus, email, yang terkait dengan semua lembar kerja di buku kerja Excel ini, akan ditampilkan di Outlook.
8. Terakhir, Anda dapat memeriksa kembali semua detail email dan terakhir klik tombol “Kirim” untuk mengirim email keluar.

Terapkan Alat Pemulihan yang Ampuh jika Tidak Ada Cadangan

Semakin banyak pengguna yang memahami pentingnya backup data. Selama Anda telah mencadangkan file PST Anda, Pemulihan PST setelah kerusakan akan cukup sederhana. Tetapi jika tidak ada cadangan PST yang efektif dan terbaru, Anda tidak punya pilihan selain mengambil bantuan alat perbaikan PST eksternal, seperti DataNumen Outlook Repair. Itu dapat memperbaiki file PST yang dikompromikan dengan mudah.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com