Cara Batch Menghapus Semua Alamat Email dengan Domain Tertentu dari Kontak Outlook Anda

Terkadang, Anda mungkin berharap untuk menghapus semua alamat email dengan domain tertentu dari kontak Anda. Dalam situasi ini, Anda pasti enggan melakukannya satu per satu. Jadi, p iniost akan mengajari Anda metode yang jauh lebih cerdas.

Misalnya, sebuah perusahaan mengubah namanya. Sementara itu, domain perusahaan juga ikut berubah. Namun, di Outlook, Anda telah menyimpan banyak kontak di perusahaan ini, yang alamat emailnya menggunakan domain lama. Tentu saja, alamat email ini tidak lagi valid. Karenanya, dalam keadaan ini, jika Anda ingin menghapus alamat email ini sekaligus, Anda dapat menggunakan cara berikut.

Hapus Batch Semua Alamat Email dengan Domain Tertentu dari Kontak

1. Untuk sebagaitart, akses editor Outlook VBA dengan pintasan tombol - “Alt + F11”.
2. Kemudian, di jendela baru, letakkan kode VBA berikut dalam modul kosong.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Setelah itu, letakkan kursor di subrutin “BatchRemoveAllEmailAddressesInSpecificDomain”.
4. Terakhir, klik tombol "F5" untuk memicu makro ini.
5. Selanjutnya, masukkan domain tertentu kotak dialog popup.
6. Setelah klik "OK", makro akan berjalan.
7. Setelah selesai, Anda akan mendapatkan pesan tentang hasilnya.
8. Sekarang, Anda dapat memeriksa kontaknya. Semua alamat email dengan domain tertentu pasti sudah hilang.

Pertahankan File Outlook Anda

Dengan semakin banyaknya risiko seputar Outlook Anda, semakin sulit untuk melindungi data Outlook Anda yang berharga. Misalnya, Anda tidak hanya harus terus melakukan pencadangan data biasa, tetapi juga harus berhati-hati terhadap operasi Anda. Tidaklah bijaksana untuk selalu percaya pada email apa pun dari pengirim yang tidak dikenal. Jika tidak, jika membawa virus, file Outlook Anda akan terinfeksi. Pada saat itu, Anda harus berusaha Perbaikan Outlook melalui alat perbaikan yang luar biasa, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan Sql Server dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com