Cara Batch Ekspor Semua Email dalam Percakapan sebagai File Teks melalui Outlook VBA

Terkadang, Anda mungkin ingin menangkap semua email dalam percakapan tertentu dan kemudian mengekspornya ke folder lokal sebagai file Teks. Artikel ini akan mengajari Anda cara mendapatkannya dalam waktu cepat.

Untuk beberapa alasan, Anda mungkin perlu mengekspor semua email dalam percakapan tertentu ke drive lokal Anda. Jika Anda melakukan ini secara manual, yaitu menemukan dan menyimpan satu per satu, itu akan menjadi tugas yang membosankan dan berat. Oleh karena itu, sebaiknya Anda mencari cara lain yang lebih cepat, seperti berikut ini. Ini akan menggunakan sepotong kode VBA untuk mendapatkannya tanpa berkeringat.

Ekspor Batch Semua Email dalam Percakapan sebagai File Teks

1. Pertama-tama, luncurkan aplikasi Outlook Anda.
2. Kemudian tekan tombol "Alt + F11" untuk mengakses editor Outlook VBA.
3. Selanjutnya, di jendela baru, Anda perlu membuka modul yang tidak digunakan atau langsung memasukkan modul baru.
4. Selanjutnya Anda harus menyalin dan menempelkan kode VBA berikut ke dalam modul ini.

Public strFilePath, strFileName As String

Sub ExportMailsInConversationAsTXT()
    Dim objSelectedMail As Outlook.MailItem
    Dim objConversation As Outlook.Conversation
    Dim objMail As Outlook.MailItem

    Set objSelectedMail = ActiveExplorer.Selection.Item(1)
    Set objConversation = objSelectedMail.GetConversation
 
    If Not (objConversation Is Nothing) Then
       'Get all root items in this conversation
       For Each objMail In objConversation.GetRootItems
 
          strFileName = objMail.Subject
 
          'Remove the unsupported characters in email subject
          strFileName = Replace(strFileName, "/", " ")
          strFileName = Replace(strFileName, "\", " ")
          strFileName = Replace(strFileName, ":", "")
          strFileName = Replace(strFileName, "?", " ")
          strFileName = Replace(strFileName, Chr(34), " ")

          strFileName = Format(objMail.ReceivedTime, "YYYY-MM-DD") & "_" & strFileName & ".txt"
 
         'Export as Text files
         'Change "E:\" to other local folder path as per your needs
         strFilePath = "E:\" & strFileName
         objMail.SaveAs strFilePath, OLTXT

         'Process all children as well
         Call ProcessChildren(objMail, objConversation)
      Next
   End If

   MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessChildren(objCurMail As Outlook.MailItem, objCurConversation As Outlook.Conversation)
    Dim objItems As Outlook.SimpleItems
    Dim objItem As Outlook.MailItem
 
    Set objItems = objCurConversation.GetChildren(objCurMail)

    If objItems.Count > 0 Then
       For Each objItem In objItems
 
           strFileName = objItem.Subject
 
           strFileName = Replace(strFileName, "/", " ")
           strFileName = Replace(strFileName, "\", " ")
           strFileName = Replace(strFileName, ":", "")
           strFileName = Replace(strFileName, "?", " ")
           strFileName = Replace(strFileName, Chr(34), " ")
 
           strFileName = Format(objItem.ReceivedTime, "yyyy-mm-dd") & "_" & strFileName & ".txt"
 
           strFilePath = "E:\" & strFileName
           objItem.SaveAs strFilePath, OLTXT
 
           'Process all children recursively
           Call ProcessChildren(objItem, objCurConversation)
       Next
    End If
End Sub

5. Setelah itu, Anda dapat menambahkan proyek VBA baru ke Bilah Alat Akses Cepat seperti biasa.
6. Nanti pastikan tingkat keamanan makro Outlook Anda ke rendah.
7. Terakhir, Anda bisa mencobanya.

• Pertama, pilih email.
• Lalu klik tombol makro baru di Bilah Alat Akses Cepat.
• Ketika Anda mendapatkan pesan "Lengkap", Anda dapat membuka folder lokal yang telah ditentukan, di mana Anda akan melihat email dalam format "TXT".

Tips Memulihkan Data PST setelah Korupsi

Seringkali, di Outlook, Anda mungkin menemukan berbagai kesalahan Outlook, beberapa di antaranya bisa sangat serius sehingga langsung mengarah ke korupsi PST. Pada saat itu, Anda perlu mengambil tindakan untuk memperbaiki PST file untuk menemukan kembali data berharga Anda. Dalam hal ini, Anda dapat menggunakan alat yang memiliki reputasi baik dan terbukti dengan baik, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan sql server dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com