2 Cara Cerdas Mengurutkan Kolom Teks berdasarkan Panjangnya di Word Anda

Dalam artikel hari ini, kami akan menunjukkan kepada Anda 2 cara cerdas untuk mengurutkan kolom teks berdasarkan panjangnya di Word Anda.

Ada beberapa cara untuk mengurutkan kolom teks atau angka dalam tabel. Tapi, pernahkah Anda terpikir untuk mengurutkan kolom teks berdasarkan panjangnya? Jika demikian, tata letak dokumen Anda akan lebih jelas dan mudah dibaca.

Namun, tidak ada cara langsung di Word bagi kami untuk mengurutkan dalam aturan ini. Oleh karena itu, kami harus mencari solusi untuk mengatasi masalah tersebut.

Metode 1: Gunakan Word VBA

Misalnya, kita memiliki tabel seperti di bawah ini:

1. Pertama dan terpenting, di Word tekan “Alt+F11” untuk mengaktifkan editor VBA.
2. Pergi untuk membuat modul baru dengan mengklik "Normal" di kolom kiri.
3. Kemudian klik tab "Sisipkan" dan pilih "Modul" pada menu drop-down.
4. Selanjutnya, klik dua kali pada modul untuk membukanya dan tempelkan makro di bawah ini:

Sub SortByWordLength()
  Dim objTable As Table
  Dim objColumnCell As Cell
  Dim objColumnCellRange As Range
  Dim objNewColumnCellRange As Range
  Dim nRowNumber As Integer
  Dim nColumnNumber As Integer
  Dim strWordLenth As String
  Dim nSortOrder As Integer
  Dim nCurrentTableIndex As Integer
  Dim nTableColumnsInCurrentTable As Integer
 
  nCurrentTableIndex = ActiveDocument.Range(0, Selection.Tables(1).Range.End).Tables.Count
  nTableColumns = ActiveDocument.Tables(nCurrentTableIndex).Columns.Count

  nColumnNumber = InputBox("Enter the column number you want to sort", "Column Number", "For example:2")
 
  If nColumnNumber > 0 And nColumnNumber <= nTableColumns Then
    nSortOrder = InputBox("Choose the sort order:" & vbNewLine & "If you want to sort by descending, click 1" & vbNewLine & "If you want to sort by ascending, click 0", "Sort Order", "For example:1")

    If nSortOrder = 1 Or nSortOrder = 0 Then
      '  Add a new column to put the word length of the specified column. 
      Set objTable = ActiveDocument.Tables(nCurrentTableIndex)
      objTable.Columns.Add BeforeColumn:=objTable.Columns(nColumnNumber)
      nRowNumber = 1

      For Each objColumnCell In objTable.Columns(nColumnNumber + 1).Cells
        Set objColumnCellRange = objColumnCell.Range
        objColumnCellRange.MoveEnd Unit:=wdCharacter, Count:=-1
        Set objNewColumnCellRange = objTable.Cell(nRowNumber, nColumnNumber).Range
        objNewColumnCellRange.MoveEnd Unit:=wdCharacter, Count:=-1
 
        strWordLenth = Len(objColumnCellRange.Text)
 
        objNewColumnCellRange.InsertAfter (strWordLenth)
 
        nRowNumber = nRowNumber + 1
      Next objColumnCell
 
      objTable.Select
 
      '  Sort by the word length. 
      Selection.Sort ExcludeHeader:=True, FieldNumber:="Column " & nColumnNumber, SortFieldType:= _
        wdSortFieldNumeric, SortOrder:=nSortOrder, FieldNumber2:="", _
        SortFieldType2:=wdSortFieldAlphanumeric, SortOrder2:=wdSortOrderAscending _
      ,  FieldNumber3:="", SortFieldType3:=wdSortFieldAlphanumeric, SortOrder3:= _
        wdSortOrderAscending, Separator:=wdSortSeparateByCommas, SortColumn:= _
        False, CaseSensitive:=False, LanguageID:=wdEnglishUS, SubFieldNumber:= _
        "Paragraphs", SubFieldNumber2:="Paragraphs", SubFieldNumber3:="Paragraphs"
 
      objTable.Columns(nColumnNumber).Delete
 
    Else
      MsgBox ("Invalid sort type, please try again")
    End If
  Else
    MsgBox ("Invalid column number, please try again")
  End If
End Sub

Note:

Jika tabel Anda tidak berisi baris header, maka Anda perlu mengubah baris kode berikut:

Selection.Sort ExcludeHeader:=True

Ganti "Benar" dengan "Salah".

5. Selanjutnya klik "Jalankan".
6. Kemudian di kotak pertama yang terbuka, masukkan nomor kolom dari kolom target, misalnya “2” untuk kolom kedua.
7. Klik "OK".
8. Di kotak kedua, masukkan angka untuk menentukan aturan pengurutan. “0” mewakili pengurutan dengan menaik, “1” dengan menurun.
9. Demikian pula, klik "OK".

Periksa efeknya:

Metode 2: Urutkan di Excel

1. Pertama, pilih tabel di Word dan tekan "Ctrl + C" untuk menyalinnya.
2. Selanjutnya buka Excel dan paste dengan menekan "Ctrl + V". Sekarang jika tabel Anda tidak memiliki baris header, lalu tempelkan tabel di sel A2.
3. Kemudian klik huruf kolom pada kolom tersebut. Misalnya, anggap saja kolom C adalah kolom target. Anda akan melihat kolom total dalam pilihan.
4. Selanjutnya klik kanan dan pilih "Sisipkan".
5. Akan ada kolom baru sebelum kolom C. Posisikan kursor di sel kedua kolom baru.
6. Masukkan "= LEN (C2)" di sel B2. Ingatlah untuk mengganti "C" dengan yang sebenarnya.
7. Selanjutnya letakkan kursor di pojok kanan bawah sel B2 hingga berubah menjadi tanda silang.
8. Sekarang klik dua kali. Anda akan melihat kolom baru diisi dengan angka. Ini adalah jumlah karakter untuk teks di kolom C.
9. Masukkan apa pun yang Anda suka di sel B1. Jangan biarkan kosong.
10. Letakkan kursor di sel mana pun di kolom B yang memiliki angka.
11. Klik tab "Beranda" dan klik "Urutkan & Filter".
12. Pada menu drop-down, pilih "Sortir dari Yang Terkecil ke Terbesar" atau "Urutkan Terbesar ke Terkecil".
13. Terakhir, pilih kolom yang baru disisipkan dan klik kanan untuk memilih "Hapus". Dan tempel tabel kembali ke dokumen Word.

Perbaiki Dokumen yang Rusak

Apakah Anda yakin dokumen Anda yang tersimpan di komputer aman? Meskipun Anda dapat melindungi komputer Anda dari serangan, masih ada kemungkinan dokumen hilang. Jadi, ingatlah bahwa file Anda mungkin tidak sepenuhnya aman. Oleh karena itu, dapatkan perlindungan yang memadai. pemulihan docx alat sebelumnya akan menjadi pilihan yang baik.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk xls rusak ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com