2 Cara Cepat untuk Menemukan atau Menghapus Kalimat yang Mengandung Teks Tertentu di Word Anda

Pada artikel ini, kami akan menawarkan kepada Anda 2 cara cepat untuk menemukan atau menghapus kalimat yang mengandung teks tertentu di Word Anda.

Kita semua tahu bahwa kita dapat menggunakan fungsi "Cari dan Ganti" di Word untuk dengan mudah menemukan semua kemunculan kata tertentu. Kemudian kita tidak akan kesulitan untuk menyorot, mengganti, atau menghapusnya. Seperti yang Anda lihat, targetnya adalah sebuah kata atau frasa. Namun, hari ini kami dengan senang hati memberi tahu Anda cara makro untuk menemukan atau menghapus kalimat yang berisi teks tertentu.

Metode 1: Temukan atau Hapus Kalimat yang Mengandung Teks Tertentu

1. Untuk memulai, tekan "Alt + F11" untuk memicu editor VBA di Word.
2. Selanjutnya buat modul baru dengan mengklik "Normal".
3. Kemudian klik "Sisipkan" dan pilih "Modul" untuk mendapatkan yang baru.
4. Dan buka modul dengan klik dua kali.
5. Sekarang tempel kode berikut:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Selanjutnya klik "Jalankan".
7. Akan ada kotak input, meminta Anda untuk memasukkan teks. Cukup ketikkan teks umum yang berisi semua kalimat. Klik "OK".
8. Kemudian Anda akan melihat kalimat yang berisi teks yang dipilih dengan kotak pesan yang muncul. Klik "Ya" untuk menghapus kalimat dan "Tidak" untuk menyimpannya.
9. Setelah konfirmasi, kalimat berikutnya dengan teks yang ditentukan akan terpilih. Dan ada juga kotak konfirmasi. Dengan kata lain, makro akan memandu Anda melalui seluruh dokumen, menemukan kalimat target, dan meminta konfirmasi Anda setiap kali.

Metode 2: Temukan atau Hapus Kalimat yang Mengandung Teks Apa Pun di Daftar

Dengan makro di metode 1, Anda hanya dapat mencari satu kata atau frase dalam satu waktu. Tentu saja, Anda dapat menjalankan makro berulang kali untuk mencari beberapa contoh kata atau frasa. Untuk memenuhi kebutuhan banyak pencarian, kami akan memberikan Anda makro lain.

1. Pertama, masukkan semua teks target ke dalam dokumen baru. Pastikan setiap bagian teks menempati satu paragraf tanpa spasi di akhir. Tutup dan simpan dokumen.
2. Selanjutnya instal dan jalankan makro dengan langkah-langkah yang tepat di metode 1.
3. Kemudian ganti makro dengan yang ini:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Sekarang jendela "Browse" akan terbuka. Pilih dokumen yang baru saja disimpan dan klik "Buka".
5. Prosedur berikut ini sama seperti di metode 1.

Pendekatan untuk Menangani Dokumen yang Rusak

Kehilangan data berharga benar-benar menghancurkan. Bahkan dapat membuat bisnis Anda dipertaruhkan. Untuk menghindari frustrasi seperti itu, Anda perlu menghubungi a Perbaikan kata alat sesegera mungkin. Alat seperti itu akan membantu Anda memenangkan pertempuran dengan korupsi dokumen.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaiki Excel ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com