2 Metode untuk Mengekspor Rentang Tanggal Tertentu dari Kalender Outlook Anda sebagai File iCalendar (.ics)

Bagikan sekarang:

Artikel ini akan berbagi tentang 2 pendekatan untuk mengekspor rentang tanggal tertentu kalender Outlook sebagai file iCalendar (.ics). Anda dapat memilih sesuai keinginan Anda.

Di Outlook, Anda dapat mengekspor seluruh kalender sebagai file iCalendar (.ics) hanya melalui fitur "Simpan sebagai". Namun, jika Anda ingin dengan cepat mengekspor rentang tanggal tertentu dari kalender sebagai iCalendar, baik fungsi "Simpan sebagai" atau "Ekspor" tidak dapat membantu. Jadi, di sini kami akan memperkenalkan 2 cara untuk Anda.

2 Metode untuk Mengekspor Rentang Tanggal Tertentu dari Kalender Outlook Anda sebagai File iCalendar (.ics)

Metode 1: Ekspor dengan Fitur "Kalender Email"

  1. Pertama-tama, luncurkan aplikasi Outlook Anda.
  2. Kemudian beralih ke area "Kalender".
  3. Selanjutnya Anda harus memilih kalender tertentu di panel navigasi kiri.
  4. Setelah itu, Anda harus mencari dan menekan tombol "Kalender Email" di pita.Kalender Email
  5. Sekaligus, email baru akan muncul dengan kotak dialog "Kirim Kalender melalui E-mail".
  6. Sekarang, Anda dapat menentukan rentang tanggal di kotak dialog ini, seperti gambar di bawah ini:Tentukan rentang tanggal
  7. Setelah Anda mengklik tombol "OK", kalender dalam rentang tanggal yang ditentukan akan diubah menjadi file iCalendar, dilampirkan dalam email saat ini.
  8. Selanjutnya, Anda dapat mempersempit pemeriksa Outlook saat ini hingga Anda melihat desktop Windows Anda.
  9. Akhirnya, Anda dapat menarik dan melepas file ics terlampir ke desktop, yang ditunjukkan seperti gambar di bawah ini:Seret dan jatuhkan file ics terlampir ke desktop

Metode 2: Ekspor melalui Outlook VBA

  1. Sebagai langkah awal, di jendela utama Outlook, tekan tombol “Alt + F11”.
  2. Selanjutnya Anda akan masuk ke editor Outlook VBA dengan sukses, di mana Anda harus membuka modul kosong.
  3. Selanjutnya, salin kode VBA berikut ke dalam modul ini.
Sub ExportCalender_inSpecificDateRange_AsiCalendarFile()
    Dim objCalendarFolder As Outlook.Folder
    Dim objCalendarExporter As Outlook.CalendarSharing
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objShell As Object
    Dim objSavingFolder As Object
    Dim strSavingFolder As String
    Dim striCalendarFile As String
 
    'Get the current Calendar folder
    Set objCalendarFolder = Outlook.Application.ActiveExplorer.CurrentFolder
 
    If Not objCalendarFolder Is Nothing And objCalendarFolder.DefaultItemType = olAppointmentItem Then
       Set objCalendarExporter = objCalendarFolder.GetCalendarExporter
 
       'Enter the specific start date and end date
       dStartDate = InputBox("Enter the start date, such as 7/1/2017:", "Specify Start Date")
       dEndDate = InputBox("Enter the end date, such as 8/31/2017:", "Specify End Date")
 
       If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
          'Select a Windows folder for saving the exported iCalendar file
          Set objShell = CreateObject("Shell.Application")
          Set objSavingFolder = objShell.BrowseForFolder(0, "Select a folder:", 0, "")
          strSavingFolder = objSavingFolder.self.Path
 
          If strSavingFolder <> "" Then
             striCalendarFile = strSavingFolder & "\" & "Calendar from " & Format(dStartDate, "YYYY-MM-DD") & " to " & Format(dEndDate, "YYYY-MM-DD") & ".ics"
 
             'Export the calendar in specific date range
             With objCalendarExporter
                  .IncludeWholeCalendar = False
                  .StartDate = dStartDate
                  .EndDate = dEndDate
                  .CalendarDetail = olFullDetails
                  .IncludeAttachments = True
                  .IncludePrivateDetails = False
                  .RestrictToWorkingHours = False
                  .SaveAsICal striCalendarFile
            End With
 
            MsgBox "Calendar Exported Successfully!", vbInformation
          End If
      Else
          MsgBox "Open a calendar folder, please!", vbExclamation + vbOKOnly
      End If
    End If
End Sub

Kode VBA - Ekspor Kalender Outlook sebagai File iCalendar (.ics)

  1. Nanti, Anda dapat menambahkan makro baru ke Bilah Alat Akses Cepat.
  2. Akhirnya, Anda dapat mencoba proyek VBA ini.
  • Pertama, akses kalender yang ingin Anda ekspor.
  • Lalu klik tombol makro baru di Bilah Alat Akses Cepat.
  • Selanjutnya, Anda akan diminta untuk menentukan rentang tanggal – tanggal mulai dan tanggal akhir.Masukkan rentang tanggal – tanggal mulai dan tanggal akhir
  • Setelah itu, Anda perlu memilih folder Windows untuk menyimpan file ICS.
  • Terakhir, kalender dalam rentang tanggal tertentu akan diekspor sebagai file ICS.

Lakukan Tindakan Pencegahan yang Cukup untuk Mencegah Korupsi PST

Anda harus menerima fakta yang tidak perlu dipertanyakan lagi bahwa Outlook rentan. Oleh karena itu, disarankan untuk membuat cadangan PST secara berkala. Plus, Anda harus mengawasi semua potensi bahaya, seperti virus yang disamarkan di email. Selain itu, bijaksana untuk menyiapkan spesialis Pemulihan Outlook alat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com

Bagikan sekarang:

Komentar ditutup.