2 Cara Cepat untuk Mengekstrak Bagian dari Dokumen Word Anda

Bagikan sekarang:

Pada artikel ini, kami akan menawarkan kepada Anda 2 cara cepat dan mudah untuk mengekstrak bagian dari dokumen Word Anda ke satu atau beberapa bagian lainnya.

Sangat sering terjadi untuk mengekstrak konten dari satu dokumen ke dokumen lainnya. Dan di artikel kami sebelumnya, kami telah membahas cara mengekstrak halaman dari dokumen. Untuk informasi selengkapnya, Anda dapat merujuk ke artikel ini: 2 Cara Cepat untuk Mengekstrak Halaman Individual dari Dokumen Word Anda

Hari ini, kami akan menunjukkan cara mengekstrak berdasarkan bagian.    Ekstrak Bagian dari Dokumen Word Anda

Metode 1: Ekstrak Bagian Saat Ini ke Dokumen Baru

  1. Pertama-tama, posisikan kursor di bagian target.
  2. Selanjutnya tekan “Alt + F11” untuk memanggil editor VBA di Word.
  3. Kemudian di kolom kiri, klik "Normal".
  4. Dan di menu bar, klik "Sisipkan".
  5. Kemudian pilih "Modul" pada menu drop-down tersebut.Klik "Normal" -> Klik "Sisipkan" -> Klik "Modul"
  6. Klik dua kali untuk membuka modul baru dan tempel kode berikut di sana:
Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub
  1. Selanjutnya, klik "Run" pada menu bar atau tekan "F5".Tempel Kode-> Klik "Jalankan"
  2. Kemudian akan muncul jendela "Browse". Pilih tempat untuk menyimpan dokumen baru dan klik "OK".Pilih Storing Path-> Klik "OK"
  3. Dan di kotak "Nama File", masukkan nama untuk file baru dan klik "OK".Masukkan Nama File-> Klik "OK"

Sekarang Anda telah mengekstrak bagian tersebut ke dokumen baru.

Metode 2: Ekstrak Setiap Bagian dalam Dokumen ke Individu Baru

Dengan cara ini dapat membantu Anda memproses semua bagian dalam dokumen. Tentu saja, kami membutuhkan makro juga.

  1. Pertama-tama, buka dokumen target.
  2. Kemudian ikuti langkah-langkah di metode 1 untuk menginstal dan menjalankan makro.
  3. Hanya kali ini ganti makro itu dengan yang ini:
Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub
  1. Namun, di jendela "Jelajahi", pilih jalur penyimpanan dan klik "OK".

Perbaiki Kesalahan Kata yang Mengiritasi

Sangat umum menemukan beberapa kesalahan Word saat menggunakannya. Mungkin menyebalkan, kita harus meluangkan waktu untuk melakukannya memulihkan kata secepatnya. Karena semakin lama kami menundanya, semakin parah kehilangan datanya. Oleh karena itu, disarankan untuk mendapatkan utilitas perbaikan terlebih dahulu.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk xls rusak ke pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com

Bagikan sekarang:

Komentar ditutup.