Ինչպես արագ արտահանել Outlook-ի հանդիպումների վրա ծախսված ընդհանուր ժամանակը յուրաքանչյուր գույնի կատեգորիայում

Եթե ​​ցանկանում եք ստեղծել հաշվետվություն յուրաքանչյուր գունային կատեգորիայի նշանակումների վրա ծախսած ընդհանուր ժամանակի մասին, կարող եք օգտագործել այս հոդվածում ներկայացված մեթոդը: Այն կարող է օգնել ձեզ դա իրականացնել արագ ժամանակում՝ առանց ձեռքով հաշվելու անհրաժեշտության:

Շատ օգտատերեր սովոր են իրենց գործունեության մեծ մասը գրանցել Outlook օրացույցում: Բացի այդ, դրանք ավելի հեշտ կառավարելու և տարբերակելու համար, նրանք կատեգորիաներ են հատկացնում դրանցից յուրաքանչյուրին: Այս դեպքում որոշ օգտատերեր կցանկանային ստեղծել հաշվետվություն, որը ցույց կտա յուրաքանչյուր գունային կատեգորիայի օրացույցի տարրերի վրա ծախսված ընդհանուր ժամանակը: Անկասկած, դժվար է հաշվարկել և մուտքագրել ձեռքով: Հետևաբար, այստեղ մենք կներկայացնենք մի եղանակ, որը կարող է կատարել այս առաջադրանքը մեկ պարզ սեղմումով:

Արտահանեք յուրաքանչյուր գույնի կատեգորիայի հանդիպումների վրա ծախսված ընդհանուր ժամանակը

1. Առաջին հերթին գործարկեք ձեր Outlook հավելվածը:
2. Այնուհետև Outlook-ի պատուհան մուտք գործելուց հետո կարող եք սեղմել «Alt + F11» ստեղնաշարի կոճակները:
3. Դրանից հետո դուք մուտք կունենաք «Microsoft Visual Basic հավելվածների համար» պատուհան:
4. Հաջորդը, դուք պետք է միացնեք «Microsoft Excel Object Library»-ն։ Կարող եք սեղմել «Գործիքներ» > «Հղում»՝ այն միացնելու համար։
5. Այնուհետև դուք պետք է գտնեք և բացեք մի մոդուլ, որը չի օգտագործվում:
6. Դրանից հետո դուք պետք է պատճենեք հետևյալ VBA կոդը այս մոդուլում.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Ի վերջո, դուք կարող եք գործարկել այս մակրոն, անկախ նրանից՝ սեղմելով «Գործարկել» պատկերակը գործիքագոտում կամ սեղմելով «F5» կոճակը:
8. Այնուհետև ձեզանից կպահանջվի ընտրել կոնկրետ օրացույց:
9. Ընտրելուց և «OK» սեղմելուց հետո մակրոն կշարունակի աշխատել: Ավարտելուց հետո նոր Excel ֆայլ կլինի, որը կցուցադրվի հետին պլանում:
10. Դուք կարող եք մուտք գործել այն: Այն նման կլինի հետևյալ սքրինշոթին.

Հետևեք ձեր Outlook-ի շուրջ հնարավոր սպառնալիքներին

Outlook-ի օգտատերերը պետք է ուշադրություն դարձնեն բոլոր հնարավոր ռիսկերին, ներառյալ անհայտ էլփոստի հավելվածները, ներկառուցված հղումները և մարդկային սխալները: Հակառակ դեպքում, ձեր Outlook-ը ցանկացած պահի կարող է փչանալ: Բացի այդ, Outlook-ի տվյալների կանոնավոր կրկնօրինակումներ պատրաստելը և վերանորոգման մասնագիտացված գործիք պահելը անհրաժեշտ են: DataNumen Outlook Repair ամենաշատ խորհուրդ տրվող շտկման գործիքներից մեկն է։ Այն կարող է վերանորոգել Outlook- ը խնդիրներ մի ակնթարթում.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վնասված mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com