Ինչպես արագ արտահանել Outlook էլփոստի բոլոր պատկերի կցորդները Excel- ի աշխատանքային թերթիկ

Outlook լուծումներ Սեպտեմբեր 29, 2025

Եթե ցանկանում եք արագորեն արտահանել Outlook էլփոստի բոլոր պատկերի կցորդները Excel- ի աշխատանքային թերթիկ, կարող եք հղվել այս հոդվածին: Այստեղ մենք ձեզ ցույց կտանք ավելի արդյունավետ միջոց, քան ձեռքով արտահանելը:

Երբ դուք ստանում եք բազմաթիվ կցված նկարներ պարունակող էլ. նամակ, եթե ցանկանում եք դրանք օգտագործել Excel-ում հաշվետվություն կազմելու համար, ապա պետք է փնտրեք մի եղանակ, որը կարող է այդ պատկերները խմբաքանակով արտահանել Excel աշխատանքային թերթ: Այժմ մենք ձեզ կներկայացնենք նման մոտեցում ստորև:

Արտահանեք էլփոստի բոլոր պատկերի կցորդները Excel- ի աշխատանքային թերթիկ

Սկսելու համար նորմալ կերպով մուտք գործեք ձեր Outlook հավելված:
Դրանից հետո Outlook պատուհանում սեղմեք «Alt + F11» ստեղնաշարի դյուրանցումները, որոնք կբերեն «Microsoft Visual Basic ծրագրերի համար» պատուհանը:
Այս էկրանին անհրաժեշտ է բացել չօգտագործվող մոդուլ կամ ուղղակիորեն տեղադրել նորը:
Հաջորդը, դուք պետք է պատճենեք ներքևում գտնվող VBA կոդի կտորը այս մոդուլի մեջ:

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

Դրանից հետո կարող եք դուրս գալ մակրոից:
Դրանից հետո անցեք «Ֆայլ»> «Ընտրանքներ»> «Արագ մուտքի գործիքագոտի» ՝ այս մակրոտն արագ մուտքի գործիքագոտում ավելացնելու համար:
Վերջապես, այս մակրոը կարող եք փորձել հենց հիմա:

Նախ, ընտրեք կամ բացեք աղբյուրի էլ. Փոստ:
Դրանից հետո կտտացրեք մակրո կոճակին Արագ մուտքի Գործիքադարակում:
Մակրոյի ավարտից հետո դուք կստանաք Excel- ի աշխատանքային թերթիկ, որը ցուցադրվում է հետևյալ սքրինշոթի նման.

Պաշտպանեք Outlook ֆայլը կոռումպացվածությունից

Հայտնի է, որ Outlook- ը հակված է կոռուպցիայի: Հետևաբար, մենք պետք է հասկանանք, թե ինչպես պաշտպանել Outlook- ի կոռուպցիան: Առաջին հերթին, վիրուսային հարձակումները արգելափակելու համար անհրաժեշտ է տեղադրել հակավիրուսային ծրագիր և երբեք ներբեռնել անհայտ հավելվածը: Բացի այդ, մենք ավելի լավ է ձեռնամուխ լինենք վերականգնման ուժեղ գործիքի, ինչպիսին է DataNumen Outlook RepairԱյն կարող է առաջարկել ամենաարդյունավետ միջոցը դեպքում Հեռանկարային կոռուպցիա.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com