Ինչպես արագ արտահանել Outlook-ի բազմաթիվ էլփոստի բոլոր հիպերհղումները Excel

Երբ անհրաժեշտ է մեկ կամ մի քանի էլ. նամակների բոլոր հղումները հանել, հիմարություն է դրանք մեկ առ մեկ պատճենելը: Այս գրառումը ձեզ կսովորեցնի մի մեթոդ, թե ինչպես արագորեն արտահանել բազմաթիվ էլ. նամակների բոլոր հղումները Excel:

Որոշ պատճառներով, ինչպես օրինակ՝ ձեր բոլոր ուղարկված էլ. նամակներում հիպերհղումները գրանցելը, ձեզ հարկավոր է հեռացնել հիպերհղումները: Առանց որևէ կասկածի, խորհուրդ չի տրվում դրանք ձեռքով հանել և պատճենել: Դուք պետք է տենչաք շատ ավելի խելացի մոտեցման, ինչպիսին է VBA-ի օգտագործումը: Այստեղ մենք ձեզ կկիսվենք VBA կոդի նման մի կտորով, որն ի վիճակի է շատ էլ. նամակների բոլոր հիպերհղումները հեշտությամբ սեղմելով Excel արտահանել:

Արտահանել բոլոր Հիպերհղումները մի քանի նամակներում Excel

1. Սկսելու համար գործարկեք ձեր Outlook ծրագիրը սովորականի պես։
2. Այնուհետև Outlook-ի պատուհանում պետք է սեղմել «Alt + F11» կոճակները:
3. Միանգամից դուք մուտք կունենաք Outlook VBA խմբագրիչ:
4. Հետագայում, դուք պետք է միացնեք «Microsoft Word Object Library»-ն, ինչպես նաև «Microsoft Excel Object Library»-ն: Սեղմեք «Գործիքներ» > «Հղումներ» և միացրեք դրանք ի հայտ եկող երկխոսության պատուհանում:
5. Հաջորդը, դուք պետք է բացեք չօգտագործված մոդուլ, որտեղ դուք պետք է պատճենեք ստորև նշված VBA կոդը այս մոդուլում:

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Դրանից հետո դուք կարող եք դուրս գալ ընթացիկ VBA խմբագրի պատուհանից:
7. Ավելի ուշ մուտք գործեք «Outlook Options»՝ հարմարեցնելու Արագ մուտքի Գործիքադարակը նոր ավելացված մակրո Արագ մուտքի Գործիքադարակի մեջ ավելացնելու համար:
8. Վերջապես կարող եք նկարահանել.

• Նախ, էլփոստի ցանկում ընտրեք այն նամակները, որոնց գերհղումները ցանկանում եք հանել:
• Դրանից հետո կտտացրեք մակրո կոճակին Արագ մուտքի գործիքագոտում:
• Երբ մակրոն ավարտվի, դուք կստանաք Excel ֆայլ, ինչպես ստորև ներկայացված պատկերը.

Ուղղել Outlook-ի անսպասելի խնդիրները

Outlook-ի հետ կապված խնդիրներ կարող են առաջանալ ժամանակ առ ժամանակ՝ առանց որևէ նախանշանի։ Սակայն, փոքր սխալների առումով, Outlook-ը կարող է վերականգնվել պարզ վերագործարկմամբ կամ դրա միջոցով։ մուտքի արկղի վերանորոգման գործիք. Բայց եթե բախվելով որոշ ծանր անախորժությունների, ներքին միջոցները ազդեցություն չեն ունենա։ Այս պահին ձեր վերջին միջոցը միանշանակ ավելի հեղինակավոր և ամուր գործիք է, ինչպիսին է DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում կոռումպացված mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com