Ինչպես արագ սեղմել բոլոր կցորդները ա Zip Պատկերացրեք ձեր Outlook էլ. Փոստում

Outlook լուծումներ Սեպտեմբեր 29, 2025

Երբեմն, դուք կարող եք ցանկանալ սեղմել բոլոր հավելվածները էլփոստի մեջ zip ֆայլ անմիջապես Outlook-ում: Այս դեպքում այս հատկությանը հասնելու համար կարող եք օգտագործել այս հոդվածում ներկայացված VBA կոդը:

Լռելյայնորեն, Outlook-ն ունի իր հավելվածի չափի սահմանաչափը` 20 ՄԲ POP3, IMAP կամ վեբ վրա հիմնված այլ էլփոստի հաշիվների համար և 10 ՄԲ Exchange հաշիվների համար: Այսպիսով, երբ հավելվածների ընդհանուր չափը գերազանցի սահմանը, դուք կստանաք համապատասխան սխալներ: Այս դեպքում լավ տարբերակ է բոլոր կցորդները սեղմել ա zip ֆայլը.

Այնուամենայնիվ, ինչպես տեսնում եք, Outlook-ը նման ուղղակի հնարավորություն չի առաջարկում: Այսինքն՝ նախ պետք է zip այս ֆայլերը կոշտ սկավառակի վրա և այնուհետև նորից կցեք նոր ստեղծվածը zip ֆայլը։ Իրականում, օգտատերերի մեծ մասը հույս ունի, որ կարող են դա անմիջապես իրականացնել Outlook-ի միջոցով։ Այս պահանջին ի պատասխան, ստորև կներկայացնենք, թե ինչպես օգտագործել VBA-ն դա իրականացնելու համար։

Սեղմեք բոլոր հավելվածները a Zip Ֆայլ

Առաջին հերթին գործարկեք ձեր Outlook հավելվածը:
Դրանից հետո հիմնական Outlook պատուհանում սեղմեք «Alt + F11» ստեղնաշարի կոճակները:
Հաջորդը նոր Outlook VBA խմբագրիչի պատուհանում բացեք մոդուլը:
Այնուհետև պատճենեք և տեղադրեք հետևյալ VBA կոդերը մոդուլի մեջ:

Sub ZipAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim objShell As Object
    Dim varTempFolder As Variant
    Dim varZipFile As Variant
 
    'Save the attachments to Temporary folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    varTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "dd-mm-yyyy- hh-mm-ss-")
    MkDir (varTempFolder)
    varTempFolder = varTempFolder & "\"
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        objAttachment.SaveAsFile (varTempFolder & objAttachment.FileName)
    Next
 
    'Create a new zip file
    varZipFile = InputBox("Specify a name for the new zip file", "Name Zip File", objMail.Subject)
    varZipFile = objFileSystem.GetSpecialFolder(2).Path & "\" & varZipFile & ".zip"
    Open varZipFile For Output As #1
    Print #1, Chr$(80) & Chr$(75) & Chr$(5) & Chr$(6) & String(18, 0)
    Close #1
 
    'Copy all the saved attachments to the new zip file
     Set objShell = CreateObject("Shell.Application")
     objShell.NameSpace(varZipFile).CopyHere objShell.NameSpace(varTempFolder).Items

     'Keep macro running until Compressing is done
     On Error Resume Next
     Do Until objShell.NameSpace(varZipFile).Items.Count = objShell.NameSpace(varTempFolder).Items.Count
        Application.Wait (Now + TimeValue("0:00:01"))
     Loop
     On Error GoTo 0
 
     'Delete all the attachments
     Set objAttachments = objMail.attachments
     While objAttachments.Count > 0
           objAttachments.Item(1).Delete
     Wend
 
     'Add the new zip file to the current email 
     objMail.attachments.Add varZipFile
 
    'Prompt
    MsgBox ("Complete!")
End Sub

Դրանից հետո դուք պետք է ստուգեք ձեր Outlook մակրո կարգավորումները՝ համոզվելու համար, որ մակրոները թույլատրված են:
Ավելի ուշ դուք կարող եք սովորականի պես ավելացնել նոր VBA նախագիծը հաղորդագրությունների պատուհանի Արագ մուտքի գործիքագոտում:
Ի վերջո կարող եք փորձել:

Նախ, ստեղծեք նոր նամակ և կցեք մի քանի ֆայլ: Կամ պարզապես բացեք բազմաթիվ հավելվածներով նամակ:
Հաջորդը կտտացրեք մակրո կոճակին Արագ մուտքի գործիքագոտում:
Հետագայում դուք պետք է նշեք անունը zip ֆայլ և սեղմեք «OK»: Լռելյայնորեն այն կսահմանվի նույնը, ինչ փոստի թեման:
Միանգամից բոլոր կցորդները կսեղմվեն ա zip ֆայլ, ինչպես հետևյալ սքրինշոթը.

Անջատեք այն .Zip Կցորդներ ուղղակիորեն Outlook- ում

Անխուսափելի է, որ դուք կստանաք ցանկացած կցորդ «.zip«ֆայլի ընդլայնումը երբեմն-երբեմն։ Այս դեպքում, դուք կարող եք ցանկանալ անմիջապես ապասեղմել նման ֆայլերը ձեր Outlook-ից, այլ ոչ թե դրանք պահել և ապասեղմել տեղական սկավառակի վրա։ Չնայած Outlook-ը չունի նման բնօրինակ գործառույթ, դուք դեռ կարող եք օգտագործել VBA-ն այն ստանալու համար։ Ավելի մանրամասն տեղեկությունների համար կարող եք դիմել մեկ այլ հոդվածի՝ «Ինչպես բացել zip ֆայլը .Zip Կցորդներ ուղղակիորեն Outlook- ում `VBA- ի միջոցով".

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql ֆիքս և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com