Ինչպե՞ս Windows- ի թղթապանակում արագորեն կցել վերջին փոփոխված ֆայլը ձեր Outlook էլ. Փոստին

Timesամանակ առ ժամանակ դուք կարող եք ցանկանալ արագորեն գտնել և կցել վերջին փոփոխված ֆայլը Windows- ի որոշակի թղթապանակում Outlook էլ. Այս դեպքում կարող եք օգտագործել սույն հոդվածում ներկայացված մեթոդը:

Որոշ օգտատերեր ցանկանում են, որ Outlook-ը արագ գտնի և կցի Windows-ի թղթապանակում վերջին անգամ փոփոխված ֆայլը էլեկտրոնային նամակին, օրինակ՝ վերջերս ստեղծված, փոփոխված կամ պահպանված ֆայլը: Սակայն Outlook-ը չի առաջարկում նման անմիջական և բնօրինակ գործառույթ: Հետևաբար, ստորև մենք կներկայացնենք VBA կոդի մի կտոր, որը կարող է հեշտությամբ իրականացնել այն:

Կապեք վերջին փոփոխված ֆայլը Windows թղթապանակում `էլ

1. Հենց սկզբից պետք է գործարկեք ձեր Outlook ծրագիրը:
2. Հետո Outlook- ի հիմնական պատուհանը մտնելուց հետո կարող եք սեղմել «Alt + F11» ստեղնաշարի կոճակները:
3. Հաջորդաբար դուք հաջողությամբ մուտք կգործեք Outlook VBA խմբագրի պատուհանում:
4. Դրանից հետո դուք պետք է գտնեք և բացեք չօգտագործվող մոդուլ:
5. Եվ ապա պատճենեք և տեղադրեք հետևյալ VBA կոդը այս մոդուլի պատուհանում:

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Դրանից հետո դուք կարող եք դուրս գալ ընթացիկ VBA խմբագրի պատուհանից և շարունակել ավելացնել նոր մակրո արագ մուտքի գործիքագոտու կամ հաղորդագրության պատուհանի ժապավեն:
7. Ավելի ուշ դուք պետք է փոխեք ձեր Outlook մակրո անվտանգության մակարդակը ցածր:
8. Ի վերջո կարող եք փորձել:

• Նախ, ստեղծեք և կազմեք նոր Outlook էլփոստ, ինչպես միշտ:
• Դրանից հետո սեղմեք մակրո կոճակը Արագ մուտքի գործիքագոտում, ինչպես ստորև նկարը.
• Հաջորդից ձեզանից պահանջվում է ընտրել աղբյուրի Windows պանակը և սեղմել «OK»:
• Եթե ​​ընտրված Windows թղթապանակում կա նման ֆայլ, դուք կստանաք հուշում, ինչպիսին է հետևյալ էկրանի նկարը.
• Երբ «Այո» եք սեղմում, այս ֆայլը միանգամից կցվում է:

Հնարավորինս շուտ լուծեք Outlook- ի խնդիրները

Ամեն անգամ, երբ բախվում եք Outlook- ի որևէ խնդրի, խորհուրդ է տրվում լուծել դրանք հնարավորինս շուտ: Այս իրավիճակում ավելի լավ է պատրաստեք ամուր Outlook- ի շտկում գործիք նախապես, ինչպիսիք են DataNumen Outlook Repair, Այն ի վիճակի է շտկել PST սխալները և արդյունավետորեն փրկել ձեր Outlook տվյալները:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում կոռումպացված mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com