Ինչպես խմբաքանակով նշել բոլոր էլ.փոստերը որպես կարդացված VBA- ի բոլոր Outlook թղթապանակներում

Կիսվել հիմա ՝

Բազմաթիվ օգտվողներ փափագում են լուծում, որպեսզի խմբաքանակը նշեն բոլոր նամակները, ինչպես կարդացել են Outlook- ի բոլոր պանակներում, Այս հոդվածում մենք ձեզ կներկայացնենք նման մեթոդ:  

Ինչպես բոլորս գիտենք, հեշտ է թղթապանակում կարդացված բոլոր նամակները նշել: Պարզապես ընտրեք և աջ կտտացրեք պանակին և այնուհետև համատեքստի ընտրացանկում ընտրեք «Նշել բոլորը կարդացած» տարբերակը: Այնուամենայնիվ, եթե կան չընթերցված էլ.փոստ ունեցող մի քանի պանակներ, վերը նշված միջոցներով, դուք պետք է կատարեք թղթապանակների վրա մեկ առ մեկ: Դա չափազանց մտահոգիչ է: Հետևաբար, այստեղ մենք կկիսվենք ձեզ շատ ավելի արդյունավետ ձևով, որը թույլ կտա ձեզ այն մեծ մասամբ իրականացնել:

Բոլոր էլ.փոստերը խմբաքանակով նշեք որպես կարդացված Outlook- ի բոլոր թղթապանակներում

  1. Սկսելու համար գործարկեք Outlook ծրագիրը:
  2. Դրանից հետո սեղմեք «Alt + F11» ՝ Outlook VBA խմբագիր մուտք գործելու համար:
  3. Հաջորդը ՝ «Microsoft Visual Basic for Applications» պատուհանում, պատճենեք ներքևի կոդը չօգտագործված մոդուլի:
Sub MarkAllItemsAsRead()
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process all Outlook files
    Set objStores = Outlook.Application.Session.Stores
  
    For Each objStore In objStores
        Set objOutlookFile = objStore.GetRootFolder
 
        For Each objFolder In objOutlookFile.Folders
            'Process mail folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objUnreadItems As Outlook.Items
    Dim i As Integer
    Dim objItem As Object
    Dim objSubFolder As Outlook.Folder
 
    Set objUnreadItems = objCurFolder.Items.Restrict("[Unread]=True")
 
    'Mark all unread emails as read
    For i = 1 To objUnreadItems.Count
        Set objItem = objUnreadItems.Item(i)
        objItem.UnRead = False
        objItem.Save
    Next
 
    'Process subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubFolder In objCurFolder.Folders
           Call ProcessFolders(objSubFolder)
       Next
    End If
End Sub

VBA կոդ. Խմբաքանակը նշում է բոլոր էլ. Փոստերը որպես կարդացված բոլոր Outlook թղթապանակներում

  1. Դրանից հետո կուրսորը դրեք առաջին ենթածրագրի մեջ:
  2. Դրանից հետո սեղմեք «F5» ստեղնաշարի կոճակը կամ կտտացրեք գործիքագոտում «Գործարկել» պատկերակին:
  3. Ի վերջո, մակրոի ավարտից հետո կարող եք վերադառնալ փոստի պանակների ցուցակ:
  4. Այնտեղ կտեսնեք, որ բոլոր չընթերցված էլ. Փոստերը նշվել են որպես ընթերցված, ինչպես ցույց է տրված էկրանի նկարում:Բոլոր էլ.փոստերը կարդացել են

Փախչել խղճուկ Outlook տվյալների կորստից

Օգտագործողները գուցե ընդունել են մի փաստ, որ Word փաստաթղթերը և Excel աշխատանքային գրքերը կարող են հեշտությամբ ապականվել: Իրականում, այս ֆայլերի նման, Outlook տվյալների ֆայլը նույնպես հակված է վնասների: Հետևաբար, եթե դուք դժկամությամբ եք դա զգում, ապա պետք է որոշ գործողություններ կատարեք: Այն պետք է ներառի նախազգուշական միջոցներ, ինչպիսին է կանոնավոր պահուստավորումը, բոլոր վնասակար ծրագրերը կամ վիրուսները արգելափակելը և որոշ օգնության միջոցներ, ինչպիսիք են ՝ իմանալով, թե ինչպես գործարկել մուտքի արկղի վերականգնման գործիքը, Սկանպստ և արտաքին ամրագրման հզոր գործիք պահելը, ինչպիսին է DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերանորոգել mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: