Ինչպես ինքնաբերաբար վերցնել մարմնի առաջին շարքը որպես առարկա ՝ նախքան Outlook էլփոստ ուղարկելը ՝ առանց առարկայի

Որոշ օգտվողներ ցանկանում են, որ Outlook- ը ավտոմատ կերպով վերցնի էլփոստի մարմնի առաջին տողը `որպես թեմա, երբ թեմա չունի նամակ: Այժմ, այս հոդվածում մենք կներկայացնենք VBA կոդի միջոցով այն իրացնելու մեթոդ:

Բազմաթիվ օգտվողներ էլ-նամակ գրելիս և ուղարկելիս հաճախ մոռանում են մուտքագրել թեման: Այսպիսով, սովորաբար, նրանք հույս ունեն, որ Outlook- ը կարող է ավտոմատ կերպով լրացնել թեման էլ-փոստի մարմնի առաջին տողում, եթե ելքային էլ-նամակը չունի թեմա: Դրանից հետո մենք ձեզ հետ կիսվելու ենք հեշտ և հարմար մեթոդով:

Ավտոմատ վերցրեք մարմնի առաջին շարքը որպես առարկա ՝ նախքան առանց թեմայի էլ-նամակ ուղարկելը

1. Հենց սկզբից գործարկեք Outlook հավելվածը:
2. Հետո հետևելով «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում«, Դուք կարող եք մուտք գործել VBA խմբագիր:
3. Հաջորդը, VBA- ի խմբագրում ավելացրեք հղումը «MS Word Object Library »համաձայն«Ինչպես ավելացնել օբյեկտ Library Հղում VBA- ում".
4. Ավելի ուշ, պատճենեք ներքևի կոդը «ThisOutlookSession» նախագծում:

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

5. Դրանից հետո կուրսորը դրեք «Application_Startup »ենթածրագիրը և սեղմել« F5 »:
6. Վերջապես, կարող եք փորձել:

• Սկզբում ստեղծեք և կազմեք էլ-նամակ, որի բովանդակությունը միայն դատարկ է:
• Դրանից հետո կտտացրեք «Ուղարկել» կոճակին:
• Ավելի ուշ, դուք կստանաք հաղորդագրություն ՝ հարցնելով, թե արդյոք որպես թեման վերցնեք մարմնի առաջին շարքը:
• Քանի դեռ ընտրում եք «Այո» կոճակը, էլփոստի մարմնի առաջին տողը արդյունահանվելու է և օգտագործվելու է որպես թեմա, իսկ էլ-նամակը կուղարկվի:

Ապահով պահեք ձեր Outlook տվյալները

Բացարձակապես, ձեր Outlook- ում կան բազմաթիվ նշանակալից էլ-նամակներ և այլ իրեր: Այսպիսով, դուք չպետք է ցանկանաք բախվել Outlook- ի տվյալների կորստին: Դրանից հետո դուք պետք է կատարեք որոշ գործողություններ, ինչպիսիք են ձեր Outlook- ի տվյալների կանոնավոր պահուստավորումը, սովորելը օգտագործել ներկառուցված վերանորոգման գործիքը շտկել Outlook- ը սխալներ և ուժեղ արտաքին վերականգնման օգտակար գործիք պատրաստելը: DataNumen Outlook Repair լավ ընտրություն է `շնորհիվ PST- ի վերականգնման բարձր տեմպի:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com