Ինչպես ամեն օր Excel ֆայլում ավտոմատ գրանցել մուտքային էլ.փոստերի ընդհանուր քանակը

Outlook լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Այս հոդվածը կսովորեցնի ձեզ, թե ինչպես թույլ տալ Outlook- ին ավտոմատ կերպով հաշվել, թե քանի նամակ եք ամեն օր ստանում և համարը գրել Excel ֆայլում:

Շատ օգտվողներ պարտավոր են հաշվել ամեն օր ստացված էլ.փոստի ընդհանուր քանակը: Բացի այդ, ապագայում ավելի հարմար ստուգման համար շատերը սովոր են Excel ֆայլում գրանցել ընդհանուր հաշվարկը: Այս դեպքում, իհարկե, կարող եք ընտրել ամեն օր ձեռքով հաշվել և ձայնագրել: Այնուամենայնիվ, դա մի փոքր անհանգստացնող է: Եվ դուք կարող եք մոռանալ, որ երբեմն անում եք դա: Հետեւաբար, դուք պետք է ցանկանաք հարմար մեթոդ, որը կարող է ստիպել Outlook- ին ավտոմատ կերպով դա անել: Ի պատասխան այս պահանջի, մենք ձեզ կսովորեցնենք, թե ինչպես օգտագործել VBA- ն ՝ այն իրացնելու համար հետևյալ բաժնում:

Ավտոմատ գրանցեք մուտքային էլ.փոստերի ընդհանուր քանակը ամեն օր Excel ֆայլում

Ավտոմատ գրանցեք մուտքային էլ.փոստերի ընդհանուր քանակը ամեն օր Excel ֆայլում

  1. Հենց սկզբից գործարկեք ձեր Outlook հավելվածը:
  2. Ապա հիմնական Outlook պատուհանում սեղմեք «Alt + F11» ստեղնների դյուրանցումները:
  3. Հաջորդ ելակետային VBA խմբագրի պատուհանում բացեք «ThisOutlookSession» նախագիծը:
  4. Դրանից հետո պատճենեք և տեղադրեք հետևյալ VBA կոդերը այս նախագծում:
Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

VBA կոդեր - Ավտոմատ գրանցեք մուտքային էլ.փոստերի ընդհանուր քանակը ամեն օր Excel ֆայլում

  1. Հաջորդը, ստորագրեք այս կոդը և փոխեք ձեր Outlook մակրո պարամետրերը ՝ ստորագրված մակրոները թույլատրելու համար:
  2. Դրանից հետո ամեն օր անհրաժեշտ է ստեղծել կրկնվող առաջադրանք:
  • Նախ `Առաջադրանքների պատուհանում կտտացրեք« Նոր առաջադրանք »կոճակին:
  • Նոր առաջադրանքի պատուհանում սեղմեք «Կրկնում» կոճակը:
  • Այնուհետև հետագա երկխոսության դաշտում ընտրեք «Ամեն օր», «Յուրաքանչյուր 1 օր (ներ)» և «Ոչ մի ավարտի ամսաթիվ» և վերջապես սեղմեք «Լավ»:Միացնել առաջադրանքի կրկնությունը
  • Հետագայում փոխեք առաջադրանքի թեման և հիշեցումը ՝ ըստ ձեր կարիքների:Սահմանեք հիշեցում
  • Ի վերջո կտտացրեք «Պահել և փակել» կոճակին:
  1. Այսուհետ, ամեն անգամ, երբ այս առաջադրանքի հիշեցումը նախազգուշացնում է, Outlook- ը ավտոմատ կերպով հաշվելու է երեկ ստացված էլ.փոստերը, այնուհետև համարը կգրանցի Excel ֆայլում, ինչպես հետևյալ էկրանի նկարը.Excel ֆայլ էլփոստի հաշվարկի համար

Փախչել PST- ի տվյալների կորստից

Ոչ ոք պատրաստ չէ ընդունել PST- ի տվյալների մշտական ​​կորուստ: Այնուամենայնիվ, Outlook PST ֆայլը հակված է կոռուպցիայի: Հետևաբար, դուք պետք է բավարար նախազգուշական միջոցներ ձեռնարկեք, ինչպիսիք են PST- ի տվյալների հետևողական և արդի պահուստավորումը և հզոր պահպանումը: PST- ի վերականգնում գործիք հարեւանությամբ, ինչպես DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերանորոգում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: