Ինչպե՞ս ավտոմատ հաշվել ներկաներին նախքան ձեր Outlook- ում հանդիպման հրավեր ուղարկելը

Այս հոդվածը կսովորեցնի ձեզ, թե ինչպես օգտագործել Outlook VBA- ն ՝ մասնակիցների ավտոմատ հավաքագրման համար, նախքան հանդիպման հրավեր ուղարկելը: 

Նման է էլեկտրոնային նամակ ուղարկելուց առաջ ստացողներին հաշվելու նման, որոշ օգտատերեր նույնպես ցանկանում են հաշվել մասնակիցներին հանդիպման հրավեր ուղարկելուց առաջ: Ինչպես միշտ, սա նպատակ ունի գնահատել առաջարկվող հանդիպման ընդհանուր արժեքը, ապա որոշել, թե արդյոք ուղարկել նման հանդիպման հրավեր մասնակիցներին: Ավելին, քանի որ Outlook-ը թույլ է տալիս օգտատերերին սահմանել մասնակիցներին ըստ անհրաժեշտության կամ ըստ ցանկության, որոշները կցանկանային մասնակիցներին հաշվել տարբեր տեսակների: Եվ ավելի լավ չէր կարող լինել, եթե հանդիպման ռեսուրսները և տևողությունը կարողանային ներառվել: Չնայած Outlook-ը նման ուղղակի գործառույթ չունի, դուք դեռ կարող եք օգտագործել VBA կոդ՝ դա իրականացնելու համար:

Ավտոմատ հաշվեք ներկաներին նախքան հանդիպման հրավեր ուղարկելը

1. Սկսելու համար գործարկեք ձեր Outlook ծրագիրը։
2. Ապա Outlook- ի հիմնական պատուհանում սեղմեք «Alt + F11» ստեղնաշարի դյուրանցումները:
3. Հաջորդը հաջողությամբ մուտք կգործեք Outlook VBA խմբագիր: Այժմ ձեզ հարկավոր է գտնել և բացել «ThisOutlookSession» նախագիծը:
4. Դրանից հետո պատճենեք և տեղադրեք հետևյալ VBA կոդերը այս նախագծում:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMeetingInvitation As Outlook.MeetingItem
    Dim objMeeting As Outlook.AppointmentItem
    Dim objAttendees As Outlook.Recipients
    Dim objAttendee As Outlook.recipient
    Dim lRequiredAttendeeCount, lOptionalAttendeeCount, lResourceCount As Long
    Dim strMsg As String
    Dim nPrompt As Integer
 
    If TypeOf Item Is MeetingItem Then
       Set objMeetingInvitation = Item
       Set objMeeting = objMeetingInvitation.GetAssociatedAppointment(True)
       Set objAttendees = objMeetingInvitation.Recipients
    End If
 
    lRequiredAttendeeCount = 0
    lOptionalAttendeeCount = 0
    lResourceCount = 0
 
    'Count the required & optional attendees and resources, etc.
    For Each objAttendee In objAttendees
         If objAttendee.Type = olRequired Then
            lRequiredAttendeeCount = lRequiredAttendeeCount + 1
         ElseIf objAttendee.Type = olOptional Then
            lOptionalAttendeeCount = lOptionalAttendeeCount + 1
         ElseIf objAttendee.Type = olResource Then
            lResourceCount = lResourceCount + 1
         End If
    Next
 
    'Double check the meeting invitation details
    strMsg = "Meeting Details:" & vbCrLf & vbCrLf & _
     "Required Attendees: " & lRequiredAttendeeCount & vbCrLf & _
     "Optional Attendees: " & lOptionalAttendeeCount & vbCrLf & _
     "Resources: " & lResourceCount & vbCrLf & _
     "Duration: " & GetDuration(objMeeting) & vbCrLf & vbCrLf & _
     "Are you sure to send this meeting invitation?"
 
    nPrompt = MsgBox(strMsg, vbExclamation + vbYesNo, "Double Check Meeting Invitation")
 
    If nPrompt = vbYes Then
       Cancel = False
    Else
       Cancel = True
    End If
End Sub

Function GetDuration(objCurMeeting As AppointmentItem) As String
    'Convert minute to hour
    If objCurMeeting.Duration > 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hours"
    ElseIf objCurMeeting.Duration = 60 Then
       GetDuration = Round(objCurMeeting.Duration / 60, 1) & " hour"
    ElseIf objCurMeeting.Duration < 60 Then
       GetDuration = objCurMeeting.Duration & " mins"
    End If
End Function

5. Դրանից հետո դուք պետք է ստորագրեք այս կոդը:
6. Ավելի ուշ համոզվեք, որ ձեր Outlook- ը թույլ է տալիս թվանշորեն մակրո մակրոներ:
7. Այսուհետ, ամեն անգամ, երբ հրավիրատոմսերը կտտացնում եք «Ուղարկել» կոճակին, կստանաք հաղորդագրություն, որը ցույց է տալիս ներկաների քանակը, ռեսուրսները և տևողությունը, ինչպես հետևյալ պատկերը.

Fկունորեն հաղթահարել հիասթափեցնող կանխատեսումները կոռուպցիայի դեմ

Միգուցե նախկինում երբևէ բախվել եք Outlook- ի այնպիսի խնդիրների, ինչպիսիք են սառեցումը, զանազան սխալի հաղորդագրություններ և այլն: Բարեբախտաբար, Outlook- ը նախատեղադրված է մուտքի արկղի վերանորոգման գործիքով, որը կոչվում է as Սկանպստ, որն ընդունակ է լուծել փոքր խնդիրներ: Բայց եթե խնդիրը լուրջ է, ձեզանից պահանջվում է կրկին դիմել ավելի մասնագիտացված գործիքի, ինչպիսին է DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում կոռումպացված mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com