Ինչպես ավելացնել ծննդյան հիշեցումներ ձեր մուտքի տվյալների բազայում

Իմացեք, թե ինչպես կարող եք ծննդյան օրվա հիշեցումներ ավելացնել ձեր Access տվյալների բազայում: Տեղեկացե՛ք, արդյոք մոտենում է ձեր հաճախորդի կամ աշխատակցի ծննդյան օրը, որպեսզի կարողանաք նրանց ուղարկել ձեր ջերմ ողջույնը:

Ծննդյան օրվա շնորհավորանքներ ուղարկելը կարող է հիանալի միջոց լինել հաճախորդի կամ աշխատակցի հետ հարաբերությունները կապելու և ամրապնդելու համար: Եթե ​​դուք կառավարում եք Access տվյալների բազան, որը պարունակում է հաճախորդների/աշխատողների գրառումները, լավ կլինի ժամանակ առ ժամանակ տեղեկացված լինել, եթե մոտենում է հաճախորդի կամ աշխատակցի ծննդյան օրը: Այս ձեռնարկում դուք կսովորեք, թե ինչպես կարող եք ստեղծել մի ֆունկցիա, որը ձեզ կտեղեկացնի որևէ մեկի հատուկ օրվա մասին տվյալների բազան բացելու պահին:

Download Now

Եթե ​​ցանկանում եք հնարավորինս շուտ սկսել օգտագործել գործառույթը, ապա կարող եք՝

Ներբեռնեք Նմուշի շտեմարանը VBA կոդերով հիմա

Հակառակ դեպքում, եթե ցանկանում եք ինքնուրույն վարվել, կարող եք կարդալ ստորև բերված բովանդակությունը:

Նախադրյալ

Այս ձեռնարկը ենթադրում է, որ ձեր տվյալների բազայում ունեք աղյուսակ, որը պարունակում է այս 3 դաշտերը՝ անուն, ազգանուն և ծննդյան օր:

Մուտքի տվյալների բազայում ծննդյան օրվա հիշեցումներ ավելացնելու քայլեր

1. Ստեղծեք նոր աղյուսակ և անվանեք այն Ծննդյան տոնակատարներ. Սա կծառայի որպես ծննդյան տոնակատարների ցուցակի պահոց: Ավելացնել 3 դաշտ, ինչպես ցույց է տրված ստորև: Առաջնային բանալի կարիք չկա:
2. Ստեղծեք ձև ծննդյան տոնակատարների համար: Այս ձևը կհայտնվի տվյալների բազան բացելուց հետո, եթե կան գալիք ծննդյան օրեր:

• Նավիգացիոն պատուհանում ընտրեք «Ծննդյան տոնակատարներ» աղյուսակը:
• Գնացեք Ստեղծել > Ձև:
• Ձեզ համար ավտոմատ կերպով կստեղծվի մեկ ձև:

Քանի որ մենք պատրաստվում ենք ցուցադրել ծննդյան տոնակատարների ցուցակը, ես կառաջարկեի փոխել ձևի լռելյայն տեսքը կամ Տվյալների թերթիկ կամ շարունակական ձևեր: Այսպիսով, դուք կարող եք ունենալ ցուցակի արագ ակնարկ:

• Դիզայնի դիտման ժամանակ ընտրեք ձևը:
• Բացեք Հատկությունների թերթիկը (ALT + F11)
• Գնացեք Ձևաչափ > Նախնական տեսք:
• Ընտրեք ձեր ուզած տեսքը՝ կա՛մ Տվյալների թերթիկ, կա՛մ շարունակական ձևեր:

Եթե ​​ընտրել եք Continuous Forms, խմբագրեք դիզայնը՝ ձեր նախասիրություններին համապատասխան: Ահա թե ինչպիսի տեսք ունի իմը.

Ես խմբագրել եմ Birthday textbox-ի ձևաչափը, որպեսզի արժեքները ցուցադրվեն Long Date ձևաչափով: Նաև ես կատարել եմ հետևյալ թարմացումները ձևի հատկությունների վերաբերյալ.

• Թույլատրել հավելումները՝ ոչ
• Թույլատրել ջնջումները՝ ոչ
• Թույլատրել փոփոխությունները՝ ոչ

Ավարտելուց հետո փակեք ձևը և պահեք այն որպես frm_BirthdayCelebrants.

3. Ավելացրեք կոդը ծննդյան օրվա հիշեցման համար:
   • Ավելացնել նոր մոդուլ:
   • Սա կբացի VBA խմբագիրը:
   • Ավելացրեք հետևյալ կոդը և փոփոխեք այն՝ ձեր կարիքներին համապատասխան:

Public Function RunBirthdayReminders()
  Dim qry As String, fld_fName As String, fld_lName As String, fld_birthday As String, tbl As String
  Dim db As DAO.Database, rst As DAO.Recordset
 
  'TO DO: Update the ff. variables with the actual name of your table and fields
 
  tbl = "Members" 'table containing your client/employee reocrds
  fld_fName = "FirstName" 'first name field
  fld_lName = "LastName" 'last name field
  fld_birthday = "Birthday" 'birthday field
 
  Set db = CurrentDb
 
  'delete current record(s) from BirthdayCelebrants table
  DoCmd.SetWarnings False
  DoCmd.RunSQL ("DELETE FROM BirthdayCelebrants")
  DoCmd.SetWarnings True
 
  'insert new record(s) in BirthdayCelebrants table using a query that gets list of people celebrating their birthday today.
  qry = "INSERT INTO BirthdayCelebrants " & _
    "SELECT " & fld_fName & ", " & fld_lName & ", " & fld_birthday & " FROM " & tbl & " WHERE " & _
      "Month(" & fld_birthday & ")=Month(Date()) AND Day(" & fld_birthday & ")=Day(Date())"
 
  DoCmd.SetWarnings False
  DoCmd.RunSQL (qry)
  DoCmd.SetWarnings True
 
  Set rst = db.OpenRecordset("SELECT * FROM BirthdayCelebrants")
  If Not rst.EOF Then
    DoCmd.OpenForm ("frm_BirthdayCelebrants")
  End If
 
  Set db = Nothing
  Set rst = Nothing
End Function

Խնդրում ենք նկատի ունենալ, որ վերը նշված կոդը օգտագործում է հարցում, որը ստանում է ծննդյան տոնակատարների ցուցակ ընթացիկ օրվա համար: Եթե ​​ցանկանում եք ստանալ մարդկանց ցուցակը, ում ծննդյան օրը մոտենում է ընթացիկ ամսին, փոխարենը օգտագործեք հետևյալ հարցումը:

'insert new record(s) in BirthdayCelebrants table using a query that gets list of people whose birthday is coming up for this month.
qry = "INSERT INTO BirthdayCelebrants " & _
  "SELECT " & fld_fName & ", " & fld_lName & ", " & fld_birthday & " FROM " & tbl & " WHERE " & _
    "Month(" & fld_birthday & ")=Month(Date()) AND Day(" & fld_birthday & ")>=Day(Date())" & _
      " ORDER BY Day(" & fld_birthday & ") ASC"

4. Ի վերջո, մենք պատրաստվում ենք ստեղծել AutoExec մակրո: Սա կգործարկի կոդը տվյալների բազան բացելուց հետո:
   • Գնացեք Ստեղծել > Մակրո:
   • ընտրել RunCode բացվող ցուցակից:
   • Ֆունկցիայի անվան համար գրեք RunBirthdayReminders ().
   • Պահպանել մակրո որպես AutoExec եւ սեղմեք OK:

5. Այժմ փորձարկեք ձեր ծննդյան հիշեցումը:

Փակեք տվյալների բազան և նորից բացեք այն: Եթե ​​կան գալիք ծննդյան օրեր, ապա պետք է հայտնվի ծննդյան հիշեցման ձևը: Եթե ​​ոչ մեկը, տվյալների բազան կաշխատի ինչպես միշտ:

Արագ հիշեցում

Այժմ արագ հիշեցման համար: Եթե ​​մի օր չկարողանաք բացել ձեր տվյալների բազան, խուճապի մի մատնվեք: Անհրաժեշտ քայլեր ձեռնարկեք այն վերականգնելու համար։ Եթե ​​դուք դեռ չեք կարող, փորձեք երրորդ կողմի ծրագրակազմը, որը դա կլինի ամրագրել Access- ը. Դեռ հույս կա.

Հեղինակի ներածություն.

Jayme Stack- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և գերազանցել վերականգնման ծրագրային արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com