Outlook-ի առաջադրանքների ցուցակները տարբեր կատեգորիաներով տարբեր էջերում տպելու 2 եղանակ

Եթե ​​դուք տարբեր գույների կատեգորիաներ եք հատկացրել ձեր Outlook-ի առաջադրանքներին և այժմ ցանկանում եք տպել տարբեր կատեգորիաներով առաջադրանքների ցուցակները տարբեր էջերում, կարող եք անդրադառնալ այս հոդվածին: Այստեղ մենք ձեզ կկիսվենք այն ստանալու 2 եղանակով:

Ձեր առաջադրանքները դասակարգելու և լավ կառավարելու համար, հավանաբար, ձեր առաջադրանքների համար կիրառել եք գունային կատեգորիաներ: Այժմ, եթե ցանկանում եք տպել ձեր առաջադրանքների ցուցակները տարբեր կատեգորիաներով տարբեր էջերում, խնդրում ենք կարդալ: Հետևյալ հատվածում ձեզ կներկայացնենք այն ստանալու 2 միջոց։

Մեթոդ 1. Ձեռքով տպել առաջադրանքների ցուցակները մեկ առ մեկ

1. Նախ, Outlook-ում մուտք գործեք «Առաջադրանքներ» վահանակ:
2. Այնուհետև բացեք Task թղթապանակը:
3. Հաջորդը սեղմեք «Ctrl + E»՝ «Որոնում» ժապավենը ակտիվացնելու համար:
4. Դրանից հետո «Որոնում» ներդիրում սեղմեք «Դասակարգել» կոճակը:
5. Բացվող ցանկից ընտրեք գունային կատեգորիա:
6. Այնուհետև ցանկում կմնան միայն ընտրված կատեգորիայի առաջադրանքները:
7. Այժմ անցեք «Ֆայլ» > «Տպել»՝ այս առաջադրանքների ցանկը տպելու համար:
8. Այնուհետև, նույն կերպ, մեկ առ մեկ ձեռքով տպեք առաջադրանքների ցուցակները մյուս գունային կատեգորիաների հետ:

Մեթոդ 2. Խմբաքանակով տպել առաջադրանքների ցուցակները VBA-ով

1. Հենց սկզբում գործարկեք VBA խմբագրիչը՝ համաձայն «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
2. Այնուհետև ավելացրեք հղումը «MS Excel Object Library»-ին՝ համաձայն «Ինչպես ավելացնել օբյեկտային գրադարանի հղում VBA-ում".
3. Հաջորդը, պատճենեք հետևյալ VBA կոդը մոդուլի մեջ:

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Այնուհետև սեղմեք «F5» կոճակը՝ այս մակրոն անմիջապես գործարկելու համար:
5. Երբ մակրոն ավարտվի, տարբեր կատեգորիաներով առաջադրանքների ցուցակները կտպվեն տարբեր էջերում, ինչպես ցույց է տրված հետևյալ սքրինշոթում:

Վերադարձեք արժեքավոր տվյալներ վտանգված PST ֆայլից

Եթե ​​դուք ենթակա եք անհասանելի PST ֆայլի, ձեր հաջորդ քայլն անկասկած է PST- ի նորոգում. Այս դեպքում նախ կարող եք փորձել մուտքի արկղի վերանորոգման գործիքը: Պայմանով, որ այն ձախողվի, կարող եք շարունակել փորձել մեկ այլ արտաքին գործիք, ինչպիսին է DataNumen Outlook Repair. Այն ի վիճակի է արագ ժամանակում վերականգնել PST տվյալները:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում վերականգնել mdf և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com