A mellékletek kötegelt eltávolítása az elavult naptárelemekből az Outlook programban

Oszd meg most:

Ha el szeretné távolítani az elavult találkozók és értekezletek mellékleteit az Outlook programban, akkor olvassa el ezt a cikket. Itt bemutatjuk, hogyan valósíthatja meg egy lépésben.

Az Outlook-fájl méretének csökkentése érdekében erősen tanácsos megtisztítani a régi elemeket. Ez a beépített „AutoArchive” funkcióval valósítható meg, amely rendszeres időközönként automatikusan törli a régi elemeket. Egyes felhasználók azonban egyszerűen törölni kívánják a régi elemek mellékleteit anélkül, hogy magukra az elemekre hatással lenne. A következőkben megtanítjuk a mellékletek tömeges eltávolítását a régi naptárelemekből.

Mellékletek kötegelt eltávolítása az Outlook régi naptárelemeiből

Mellékletek kötegelt eltávolítása az elavult naptárelemekből

  1. Először nyissa meg az Outlook VBA szerkesztőjét az „Alt + F11” billentyűkombinációval.
  2. Ezután a „Microsoft Visual Basic for Applications” ablakban másolja be a VBA-kódot egy modulba.
Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

VBA-kód – A mellékletek kötegelt eltávolítása az elavult naptárelemekből

  1. Ezután kattintson a „BatchDeleteAttachmentsOfOldCalendarItems” makróra.
  2. Végül nyomja meg az „F5” gombot a makró futtatásához.
  3. Amikor a makró elkészült, ellenőrizheti az összes Outlook-naptárt.
  4. Az Outlooknak törölnie kell a 2 hónapnál régebbi naptárelemek összes mellékletét.Mellékletek eltávolítva az elavult naptárelemekből

Megbirkózni a sérült Outlook-fájlokkal

Találkoztál már az Outlook korrupciójával? Általában hogyan dobod ki? Leggyakrabban először a postafiókjavító eszközt próbálja ki – scanpst. Súlyos PST-károsodás esetén azonban a beépített segédprogram nem tud segíteni. Ezért javasolt egy tapasztaltabb és figyelemreméltóbb, harmadik féltől származó eszközt a közelben tartani, mint pl DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql javítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com

Oszd meg most:

Hozzászólások lezárva.