2 módszer az összes névjegy kötegelt törlésére e-mail cím nélkül az Outlook programban

Ha azt tapasztalja, hogy egyes névjegyekhez nem tartozik e-mail cím az Outlookban, érdemes lehet az egyes Névjegymappákban törölni az összes ilyen névjegyet. Ez a bejegyzés két módszert fog megosztani Önnel.

Lehet, hogy sok névjegye van az Outlookban, és néhányuknak nincs e-mail címe. Ha úgy gondolja, hogy ezek már nem használhatók, akkor remélnie kell, hogy az összes e-mail-cím nélküli névjegyet törölheti. A szokásos módon az „Azonnali keresés” segítségével megtalálhatja őket, majd manuálisan törölheti őket, például az alábbi 1. módszer szerint. Ez azonban egy kicsit unalmas. Ezért a 2. módszerben egy másik, hatékonyabb módszert fogunk megtanítani.

1. módszer: Manuális törlés az e-mail cím nélküli kapcsolatok keresése után

1. Kezdésként nyomja meg a „Ctrl + 3” billentyűkombinációt a „Névjegyek” panel eléréséhez.
2. Ezután kattintson a keresőmezőre.
3. Ezután a megjelenő „Keresés” szalagon kattintson az „Összes kapcsolattartó elemre”.
4. Ezt követően kattintson a „Van címe” > „Van e-mail címe” lehetőségre.
5. Ezt követően a „NOT emailaddresses:=[]” feltétel bekerül a keresőmezőbe. El kell távolítania a „NEM”-et.
6. Ezt követően az összes e-mail cím nélküli kapcsolat megjelenik a listában.
7. Most manuálisan kell kiválasztania a névjegyeket a keresési eredmények között, mivel a névjegycsoportoknak is szerepelniük kell a listában.
8. Végül nyomja meg a „Del” gombot az összes kiválasztott névjegy törléséhez.

2. módszer: Az összes e-mail-cím nélküli névjegy kötegelt törlése VBA-val

1. Először érintse meg az „Alt + F11” gombot a VBA-szerkesztő elindításához az Outlookban.
2. Az új képernyőn másolja be a következő VBA-kódot egy modulba.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Később kattintson a „BatchDeleteAllContactsWithoutEmailAddress” szubrutinra.
4. Végül nyomja meg az „F5” billentyűt a makró aktiválásához.
5. Amikor befejeződik, üzenetet fog kapni az eredményekről, például az alábbi képen.
6. Az összes e-mail cím nélküli névjegy a „Törölt elemek” mappába került.

Tartsa távol minden lehetséges kockázattól

Az Outlook számos tényező miatt megsérülhet, például vírusok, felhasználói hibák, szoftverhibák és hardverhibák miatt. Nem szívesen tapasztalja meg az Outlook által okozott károkat, ezért ezeket a lehetséges kockázatokat távol kell tartania. Például erős víruskereső szoftvert kell telepítenie a számítógépére. Ezenkívül rendszeresen biztonsági másolatot kell készítenie az Outlook adatairól. Végül, de nem utolsósorban jobb, ha készít egy robusztus és megbízható javítószerszámot, mint pl DataNumen Outlook Repair. Meg tudja javítani korrupt PST fájllal könnyedén.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve SQL Server korrupció és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com