3 gyors módszer az üres sorok és oszlopok törlésére a szótáblázatból

Ebben a post, elmagyarázunk Önnek 3 gyors módot az üres sorok és oszlopok törlésére a Word-táblázatból.

A táblázatok elengedhetetlenek egy dokumentumhoz, különösen a különféle típusú adatok tárolására. Néha egy hosszú táblázat meghaladhatja az oldalt, és többre is kiterjedhet. Tehát ha egy táblázat hosszú és bonyolulttá válik, néhány lépést megtehet az egyszerűsítés érdekében. Például törölheti a szükségtelen üres sorokat és oszlopokat.

A következő 3 módszer használható.

1. módszer: Az üres sorok és oszlopok manuális törlése

1. Először jelöljön ki egy sort vagy egy oszlopot üresen.
2. Ezután kattintson a jobb gombbal a helyi menü megjelenítéséhez. A menüben válassza ki a „Sorok törlése” vagy az „Oszlopok törlése” lehetőséget.

Sajnos nem lehet több nem egymást követő sort vagy oszlopot kijelölni és ezzel együtt törölni. Ehhez az igényhez korábbi cikkünkben olvashat: 5 gyors módszer több sor vagy oszlop kötegelt törlésére a Word táblázatban

2. módszer: Kötegben törölje az összes üres sort és oszlopot egy táblázatban

Az 1. módszernek megvannak a korlátai. Így felajánljuk a sorok és oszlopok kötegelt eltávolításának módját egy táblázatból VBA kódokon keresztül.

1. Kezdésként helyezze a kurzort a-be tarkap asztalt.
2. Másodszor, indítsa el a VBA-szerkesztőt az „Alt+F11” megnyomásával.
3. A szerkesztőben először kattintson a „Normál” projektre.
4. Ezután kattintson a „Beszúrás” fülre a menüsorban.
5. A legördülő menüben válassza a „Modul” lehetőséget.
6. Kattintson duplán a modulra a megnyitásához, és illessze be a következő kódokat:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Végül kattintson a „Futtatás” gombra a menüsorban, vagy nyomja meg az „F5” gombot.

Másodpercek alatt eltávolítja a táblázat összes üres sorát és oszlopát.

3. módszer: Az összes üres sor és oszlop kötegelt törlése a dokumentum összes táblázatában

1. Először ismételje meg a 2. módszer lépéseit a makró telepítéséhez és futtatásához.
2. Csak ezúttal cserélje ki a makrót a következőre:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Törött dokumentum helyreállítása

Több, mint mód van az l visszaszerzéséreost visszamenőleg napjainkban. Például mindig a biztonsági mentések készítése marad a legfontosabb prioritás. Ha ez nem elégíti ki a legfrissebb információk visszaszerzésére vonatkozó igényét, megpróbálhatja a doki javítás eszköz.

Szerző Bevezetés:

Vera Chen adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve xlsx javítás és a pdf javító szoftvertermékek. További információért látogasson el www.datanumen.com