2 módszer a kiválasztott cellák gyors elküldésére egy Excel munkalapon Outlook e-mailként

Oszd meg most:

Időnként érdemes lehet gyorsan beszúrni a kijelölt cellákat egy Excel-munkalapon egy Outlook e-mailbe, és elküldeni ezt az e-mailt. Ez a cikk ezt a kívánságot fogja megvizsgálni, és 2 módszert kínál Önnek.

Előző cikkem "2 gyors módszer Excel-munkalap küldésére Outlook e-mailként” megtanította Önnek, hogyan küldjön el egy teljes Excel-munkalapot e-mailben. Néha azonban csak a kijelölt cellákat szeretné elküldeni egy munkalapon e-mailben. Válaszul erre a követelményre, itt 2 módszert mutatunk be. Tetszés szerint bármelyiket választhatja.

2 módszer a kiválasztott cellák gyors elküldésére egy Excel munkalapon Outlook e-mailként

1. módszer: A kijelölt cellák manuális másolása e-mailbe

  1. Kezdésként nyissa meg a forrás Excel fájlt, és keresse meg a megfelelő Excel munkalapot.
  2. Ezután válassza ki azokat a cellákat, amelyeket Outlook e-mailként szeretne elküldeni.
  3. Ezután nyomja meg a „Ctrl + C” billentyűparancsokat a kijelölt cellák másolásához.Nyomja meg a „Ctrl + C” billentyűparancsokat a kijelölt cellák másolásához
  4. Ezután indítsa el az Outlook alkalmazást.
  5. Ezt követően kattintson az „Új e-mail” gombra a „Kezdőlap” szalagon egy új Outlook e-mail létrehozásához.
  6. Később az új Üzenet ablakban kattintson az üzenet törzsrészére.
  7. Ezután nyomja meg a „Ctrl + V” billentyűket a korábban másolt Excel-cellák beillesztéséhez.
  8. Végül a szokásos módon összeállíthatja az e-mailt, és a „Küldés” gombra kattintva elküldheti.

2. módszer: Küldje el a kiválasztott cellákat e-mailben VBA-n keresztül

  1. A legelején nyissa meg a forrás Excel-munkafüzetet.
  2. Ezután nyomja meg az „Alt + F11” billentyűket az Excel VBA szerkesztő eléréséhez.
  3. Az új ablakban kattintson a „Beszúrás” > „Modul” gombra egy új modul beillesztéséhez.
  4. Ezután engedélyeznie kell a Microsoft Outlook objektumokat. Kattintson az „Eszközök” > „Referenciák” menüpontra. A felugró párbeszédpanelen keresse meg és jelölje be a „Microsoft Outlook objektumtár” elemet.Engedélyezze a Microsoft Outlook objektumot az Excelben
  5. Ezt követően másolja be a következő VBA-kódot ebbe a modulba.
Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

VBA-kód – Excel-munkalap kiválasztott celláinak elküldése Outlook e-mailként

  1. Végül megpróbálhatod.
  • Először a szokásos módon válassza ki az adott cellákat.
  • Ezután térjen vissza az új makróhoz, és nyomja meg az F5 billentyűt az aktiváláshoz.
  • Egyszerre egy új Outlook e-mail jelenik meg, amelyben láthatja, hogy a kiválasztott cellák bekerültek az e-mail törzsébe, például az alábbi képernyőképen:Új e-mail, amely kiválasztott Excel-cellákat tartalmaz

A PST fájl ugyanolyan sebezhető, mint az Excel fájl

Mint tudjuk, az Excel- és Word-fájlok hajlamosak a sérülésre. Ugyanez igaz a PST-fájlokra is, amelyek az Outlook postaládájában található összes elemet tartalmazzák. Tehát nehéz feladat a PST-adatok védelme. Az egyik leghatékonyabb intézkedés a fájl rendszeres biztonsági mentése. Ráadásul az azonnali mentés érdekében jobb, ha felkészül egy tapasztalt eszközre, például DataNumen Outlook Repair, amely képes az Outlook helyreállítása adatokat anélkül, hogy izzadna.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve javítás mdf és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com

Oszd meg most:

Hozzászólások lezárva.