Hogyan akadályozhatja meg az e-mailek küldését egy adott e-mail címre az Outlook programban

Sok felhasználó azt reméli, hogy blokkolja az e-mailek véletlen elküldését egy adott e-mail címre az Outlookban. Ezért ebben a cikkben bemutatunk egy módszert ennek megvalósítására.

Az Outlook nem biztosít natív funkciókat az e-mailek egy adott e-mail címre történő küldésének letiltására. Ezért, ha meg akarja valósítani, egy kis szkriptre van szükség. A következőkben egy ilyen VBA-kódrészletet osztunk meg. Ha nem ismeri a VBA használatát, olvassa el az előző oldaltost - "A VBA kód futtatása az Outlookban".

E-mailek adott e-mail címre történő küldésének megakadályozása

1. Először nyissa meg az Outlook VBA szerkesztőjét az „Alt + F11” gombbal.
2. Ezután helyezze be a következő kódot a „ThisOutlookSession” projektbe.

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objRecipients As Outlook.Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objRecipient As Outlook.Recipient
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Expand the contact groups in Recipients
       ContactGroupFound = True
       Do While ContactGroupFound = True
          Set objRecipients = objMail.Recipients
          ContactGroupFound = False
 
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
       Loop
 
       'Remove specific email address
       For Each objRecipient In objRecipients
           If objRecipient.Address = "shelly@datanumen.com" Then
              If MsgBox("Do you want to email to " & Chr(34) & "shelly@datanumen.com" & Chr(34) & "?", vbExclamation + vbYesNo) = vbNo Then
                 objRecipient.Delete
              End If
           End If
       Next
    End If
End Sub

3. Ezt követően lépjen ki a „Microsoft Visual Basic for Applications” ablakból.
4. Végül próbálja ki a következő lépésekkel.

• Kezdésként írjon egy e-mailt, és adja meg a címzetteket.
• Ezután kattintson a „Küldés” gombra.
• A makró azonnal kibővíti a címzetteknél a névjegycsoportokat, ha vannak, és megtudja, hogy a címzettek tartalmazzák-e az adott e-mail címet.
• Ha megtalálja a címet, üzenetet fog kapni, ahogy az a következő ábrán látható.
• Ha a „Nem” lehetőséget választja, az adott e-mail cím azonnal törlődik.
• A levél elküldése után ellenőrizheti a címzettjeit, amelyek biztosan nem tartalmazzák a konkrét e-mail címet.

Javítsa ki a sérült Outlook-fájlt

Sérült már az Outlook-fájlja? Ez bevallottan a most bosszantó problémák az Outlookban. Amikor ki van téve ennek, manipulálni kell PST javítás, ami kicsit csomós. Szokás szerint most is először a Scanpst használatára fog gondolni. De sajnos ilyen esetekben meghiúsulhat. Az üdülőhelynek vagy tapasztaltabb eszköznek kell lennie, mint pl DataNumen Outlook Repair, vagy professzionális PST helyreállítási szolgáltatás.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql javítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com