Kako brzo ukloniti duplikate Outlook stavki u mapi putem VBA

Ako želite ukloniti duplicirane stavke u Outlooku, pretraživanje i uklanjanje jedne po jedne bit će prilično problematično. Ovaj članak će vas naučiti kako to brzo dovršiti pomoću Outlook VBA.

U mom prethodnom članku – “Kako brzo pronaći i ukloniti duplikate e-pošte u programu Outlook”, možete naučiti trik za pronalaženje i uklanjanje dupliciranih e-poruka, koji najprije razvrstavaju e-poruke prema predmetu, zatim prema vremenu primljenog i zatim prema privicima kako biste saznali duplicirane stavke i na kraju odaberite duplicirane i pritisnite tipku “Izbriši”. Iako je ova metoda naizgled malo praktičnija, ali je daleko problematičnija u usporedbi s korištenjem Outlook VBA. Pomoću sljedećih VBA kodova možete brzo ukloniti duplicirane stavke jednostavnim jednim klikom, bez obzira na e-poštu, zadatke, kontakte ili sastanke. Sada čitajte kako biste saznali detalje o kodovima.

Uklonite duplikate Outlook stavki u mapi

1. Za početak, pokrenite Outlook program.
2. Zatim pritisnite tipke "Alt + F11".
3. U narednom prozoru uređivača VBA dvaput kliknite da biste otvorili modul koji je u upotrebi ili izravno umetnite novi modul pomoću “Umetni” > “Modul”.
4. Zatim kopirajte i zalijepite sljedeće VBA kodove u modul.

Sub RemoveDuplicateItems()
    Dim objFolder As Folder
    Dim objDictionary As Object
    Dim i As Long
    Dim objItem As Object
    Dim strKey As String

    Set objDictionary = CreateObject("scripting.dictionary")
    'Select a source folder
    Set objFolder = Outlook.Application.Session.PickFolder

    If Not (objFolder Is Nothing) Then
       For i = objFolder.Items.Count To 1 Step -1
           Set objItem = objFolder.Items.Item(i)
 
           Select Case objFolder.DefaultItemType
                  'Check email subject, body and sent time
                  Case olMailItem
                       strKey = objItem.Subject & "," & objItem.Body & "," & objItem.SentOn
                  'Check appointment subject, start time, duration, location and body
                  Case olAppointmentItem
                       strKey = objItem.Subject & "," & objItem.Start & "," & objItem.Duration & "," & objItem.Location & "," & objItem.Body
                  'Check contact full name and email address
                  Case olContactItem
                       strKey = objItem.FullName & "," & objItem.Email1Address & "," & objItem.Email2Address & "," & objItem.Email3Address
                  'Check task subject, start date, due date and body
                  Case olTaskItem
                       strKey = objItem.Subject & "," & objItem.StartDate & "," & objItem.DueDate & "," & objItem.Body
           End Select
 
           strKey = Replace(strKey, ", ", Chr(32))
 
           'Remove the duplicate items
           If objDictionary.Exists(strKey) = True Then
              objItem.Delete
           Else
              objDictionary.Add strKey, True
           End If
       Next i
    End If
End Sub

5. Nakon toga digitalno potpišite ovu makronaredbu i promijenite razinu sigurnosti Outlook makronaredbe na nisku.
6. Kasnije možete pokrenuti ovaj novi VBA projekt. Izravno kliknite na ikonu "Pokreni" na alatnoj traci.
7. Zatim ćete morati odabrati mapu iz koje želite ukloniti duple stavke.
8. Konačno, duplicirane stavke u odabranoj mapi bit će izbrisane odjednom.

Zaštitite ranjive PST podatke

Zbog činjenice da je PST datoteka osjetljiva na korupciju, trebali biste uložiti mnogo truda da zaštitite svoju PST datoteku. Na primjer, trebali biste spriječiti nepropisno zatvaranje Outlooka. Nadalje, trebate pripremiti robusnu Outlook popravak alat, kao npr DataNumen Outlook Repair koji će moći spasiti vaš PST na vrijeme.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti se SQL Server i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com