Kako brzo ispisati sve slikovne privitke Outlook e-pošte samo na jednoj stranici

Kako bi uštedjeli tintu i papir za pisač, neki korisnici žele ispisati sve slike priložene u e-poruci samo na jednoj stranici, umjesto jedne slike po stranici. Sada će ovaj članak podijeliti načine kako to ostvariti.

Kao što svi znamo, ispisivanje slika prilično je rasipanje tinte pisača. Stoga, kako biste uštedjeli tintu i papir za pisač, možda biste radije ispisivali mnogo privitaka sa slikama na istoj stranici umjesto ispisa slika na zasebnim stranicama. Iako Outlook ne nudi takvu značajku, ipak je možete postići na sljedeći način.

Ispišite sve slikovne privitke Outlook e-pošte samo na jednoj stranici

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim u prozoru programa Outlook dodirnite gumbe s tipkama "Alt + F11".
3. Zatim ćete ući u prozor „Microsoft Visual Basic for Applications“ u kojem prvo morate omogućiti „Microsoft Word Object Library“.
4. Nakon toga potrebno je otvoriti modul koji se ne koristi.
5. Nakon toga kopirajte i zalijepite sljedeći VBA kod u ovaj modul.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Kasnije se možete vratiti na popis e-pošte. Odaberite ili otvorite e-poštu čije slikovne privitke želite ispisati.
7. Zatim pokrenite ovu makronaredbu. U trenutnom prozoru makronaredbe samo pritisnite tipku "F5" ili kliknite ikonu "Pokreni" na alatnoj traci.
8. Konačno, kada makronaredba završi s radom, svi slikovni prilozi izvorne e-pošte bit će ispisani na jednoj stranici, kao na sljedećoj snimci zaslona:

Pozabavite se oštećenim Outlook datotekama

Uz sve više i više podataka pohranjenih u vašem Outlooku, vaša Outlook datoteka postaje sve ranjivija. Može biti ugrožen zbog različitih unutarnjih i vanjskih čimbenika. Također, teško je predvidjeti oštećenje Outlooka. Dakle, ono što možete učiniti je osigurati trenutačno i učinkovito spašavanje u slučaju oštećenja Outlooka. Na primjer, morate zadržati specijaliziranog PST popravak alat, poput DataNumen Outlook Repair u blizini. Skenirati će i vratiti oštećene datoteke poput povjetarca.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti se Sql Server i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com