Kako brzo izdvojiti privitke iz svih datoteka Outlook poruka u Windows mapi

Možda ste pohranili više poruka e-pošte programa Outlook u .msg formatu u Windows mapu. A kasnije, ako želite izdvojiti privitke iz ovih datoteka, možete koristiti način podijeljen u ovom članku.

Prilično je lako izdvojiti privitke iz e-pošte u vašem Outlooku. Ali što je s e-porukama koje su izvezene kao .msg datoteke u Windows mapu? Općenito, prvo morate otvoriti te .msg datoteke u Outlooku, a zatim spremiti njihove privitke jedan po jedan. Možda ćete ga smatrati preglomaznim. Dakle, nakon toga ćemo vas naučiti drugom mnogo bržem rješenju.

Izdvojite privitke iz svih datoteka Outlook poruka u Windows mapi

1. Za početak, pokrenite Outlook aplikaciju i VBA editor.
2. Zatim u prozoru “Microsoft Visual Basic for Applications” kopirajte donji VBA kod u neiskorišteni modul.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Nakon toga pomaknite pokazivač u prvi potprogram i pritisnite tipku "F5".
4. Nakon toga, od vas će se tražiti da odaberete izvornu Windows mapu u skočnom dijaloškom okviru.
5. Nakon klika na “OK”, makro će nastaviti s radom.
6. Kada završi, primit ćete poruku "Dovršeno".
7. Sada možete dobiti pristup unaprijed definiranoj lokalnoj mapi za spremanje izdvojenih privitaka.

Učinkovito riješite Outlook probleme

Budući da je Outlook doduše sklon pogreškama, morate biti oprezni dok radite s Outlookovim objektima, kao što je nikada ne vjerovati datotekama ili vezama ugrađenim u nepoznate e-poruke i tako dalje. U suprotnom, vaša Outlook datoteka može se lako oštetiti. Pod tim okolnostima, čak ni interni alat za popravak neće biti od velike pomoći. Ono čemu možete pribjeći samo je iskusan vanjski pomoćni program, poput DataNumen Outlook Repair. To može popraviti PST turpijajte s lakoćom bez napora.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećeni sql i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com