Kako brzo izvesti Outlook mapu sa svim podmapama i stavkama u Windows mapu

Ponekad ćete možda htjeti grupno izvesti Outlook mapu sa svim podmapama i stavkama u Windows mapu. Ovaj članak će vas naučiti takvoj metodi koja je primjena Outlook VBA.

Kada želite izvesti Outlook mapu na lokalni disk sa svim stavkama u istoj strukturi mape, ako odaberete spremanje i izvoz ručno, oduzet će vam puno vremena. Stoga, zašto ne pribjegnete drugim sredstvima, kao što su alati za izvoz ili VBA kodovi? Ovdje ćemo vam otkriti takav dio VBA koda. To će vam omogućiti da to postignete poput povjetarca.

Izvezite sve podmape i stavke u Outlook mapi u Windows mapu

1. Na samom početku pokrenite Outlook.
2. Zatim u glavnom prozoru programa Outlook pritisnite prečace tipki “Alt + F11”.
3. Zatim će se pojaviti prozor "Microsoft Visual Basic za aplikacije".
4. Zatim trebate otvoriti prazan modul i u njega kopirati sljedeće VBA kodove.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Nakon toga morate osigurati da vaš Outlook dopušta makronaredbe u postavkama makronaredbi.
6. Naposljetku, možete pokušati.

• Prvo, povratak na novi makro prozor.
• Zatim kliknite na potprogram “ExportFolderWithAllItems”.
• Zatim pritisnite tipku F5 za pokretanje ove makronaredbe.
• Nakon toga morate odabrati određenu mapu.
• Na kraju, kada dobijete poruku "Dovršeno", možete pristupiti unaprijed definiranoj lokalnoj mapi. Vidjet ćete da su sve stavke spremljene u istoj strukturi mape.

Spriječite gubitak podataka zbog pada programa Outlook

Možda ste se ikada susreli s mnogim padovima Outlooka. Većinom će nakon ponovnog pokretanja Outlook moći normalno raditi. Međutim, postoji i mogućnost da se naša PST datoteka ošteti. U tom slučaju, pokušat ćete oporaviti svoje PST podatke, primjerice korištenjem iskusnog alata poput DataNumen Outlook Repair, U stanju je popraviti Outlook pogreške i izdvajanje podataka iz ugrožene PST datoteke bez preznojavanja.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući SQL Server popravak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com