Kako brzo izvesti podatke o veličini svih mapa u PST datoteci u Excel datoteku

Ako želite provjeriti podatke o veličini svake mape u PST datoteci, možete upotrijebiti metodu izloženu u ovom članku. Brzo će izvesti podatke o veličini svih mapa u PST datoteci u Excel datoteku.

Ako je vaša PST datoteka prevelika, možda ćete htjeti provjeriti veličinu svake mape. Pomoći će vam da lakše odredite koji su veći i napravite odgovarajuće arhiviranje na temelju veličine. Općenito, da biste provjerili veličinu mape, možete jednostavno kliknuti desnom tipkom miša na mapu i zatim odabrati “Svojstva”. U novom skočnom dijaloškom okviru možete kliknuti gumb "Veličina mape". Međutim, ako ste stvorili mnogo mapa, ručno provjeravanje informacija o veličini jednu po jednu prilično je problematično. Dakle, ako želite skupno dobiti informacije o veličini svih mapa u PST datoteci, možete koristiti sljedeći VBA kod. Izvest će sve nazive mapa i podatke o veličini u Excel datoteku u jednom potezu.

Izvezite podatke o veličini svih mapa u PST datoteci u Excel datoteku

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim prijeđite na karticu "Developer" i kliknite gumb "Visual Basic" ili pritisnite tipke "Alt + F11" za pristup VBA editoru.
3. Zatim u prozoru “Microsoft Visual Basic for Applications” otvorite modul koji nije u upotrebi.
4. Nakon toga kopirajte i zalijepite sljedeće VBA kodove u ovaj modul.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Nakon toga trebali biste postaviti razinu sigurnosti Outlook makroa na nisku.
6. Naposljetku, možete pokušati.

• Pritisnite tipku F5 u trenutnom prozoru makronaredbe.
• Zatim će se od vas tražiti da odaberete PST datoteku, poput sljedeće slike:
• Nakon odabira izvorne datoteke, Outlook će početi izvoziti informacije o veličini u Excel.
• Nakon završetka makronaredbe, primit ćete poruku kao na slici ispod.
• Na kraju, moći ćete pronaći Excel datoteku u unaprijed definiranoj lokalnoj mapi. Excel datoteka će izgledati ovako:

Pozabavite se čestim PST pogreškama

Budući da je Outlook sklon pogreškama, možda ste ikada imali mnogo problema s Outlookom. Kako biste se bolje i fleksibilnije nosili s frustrirajućim PST problemima, preporučljivo je u blizini držati iskusan i renomiran uslužni program za popravke, kao što je DataNumen Outlook Repair, U stanju je popraviti PST problemi kao povjetarac.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući SQL Server oporavak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com