Kako brzo izvesti sve hiperveze u više Outlook e-poruka u Excel

Kada trebate izdvojiti sve hiperveze iz jedne ili više e-poruka, glupo ih je kopirati jednu po jednu. Ovaj članak će vas naučiti metodi za brzi izvoz svih hiperveza iz više e-poruka u Excel.

Iz nekih razloga, kao što je bilježenje hiperveza u svim poslanim porukama e-pošte, morat ćete izdvojiti hiperveze. Bez ikakve sumnje, nije preporučljivo izdvajati ih i kopirati ručno. Morate čeznuti za mnogo pametnijim pristupom, kao što je korištenje VBA. Ovdje ćemo s vama podijeliti takav dio VBA koda, koji može izvesti sve hiperveze u mnogim e-porukama u Excel jednostavnim klikom.

Izvezite sve hiperveze u više poruka e-pošte u Excel

1. Za početak, pokrenite Outlook kao i obično.
2. Zatim u prozoru programa Outlook morate pritisnuti tipke "Alt + F11".
3. Odjednom ćete dobiti pristup Outlook VBA editoru.
4. Nakon toga, morate omogućiti "Microsoft Word Object Library" kao i "Microsoft Excel Object Library". Kliknite "Alati" > "Reference" i zatim ih omogućite u skočnom dijaloškom okviru.
5. Zatim morate otvoriti neiskorišteni modul, u kojem morate kopirati VBA kod ispod u ovaj modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Nakon toga možete izaći iz trenutnog prozora uređivača VBA.
7. Kasnije pristupite "Opcijama programa Outlook" da biste prilagodili alatnu traku za brzi pristup i dodali novododanu makronaredbu na alatnu traku za brzi pristup.
8. Konačno možete slikati:

• Najprije na popisu e-pošte odaberite e-poruke čije hiperveze želite izdvojiti.
• Zatim kliknite gumb makronaredbe na alatnoj traci za brzi pristup.
• Kada makronaredba završi, dobit ćete Excel datoteku, kao na slici ispod:

Riješite neočekivane probleme s Outlookom

Problemi s Outlookom mogu se povremeno pojaviti bez ikakvih znakova. Ali, u slučaju malih pogrešaka, Outlook se može oporaviti jednostavnim ponovnim pokretanjem ili njegovim... alat za popravak inboxa. Ali ako naiđete na ozbiljne probleme, unutarnja sredstva neće imati učinka. U ovom trenutku, vaše zadnje utočište je definitivno ugledniji i robusniji alat, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećeni mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com