Kako brzo izvesti pojedinosti o svim članovima u Outlook grupi kontakata u Excel

Prema zadanim postavkama možete vidjeti samo imena članova i adrese e-pošte u grupi kontakata. Ako želite dobiti ostale podatke o članovima, možete koristiti način predstavljen u ovom članku.

Kada dvaput kliknete grupu kontakata da je otvorite, u njenom prozoru možete vidjeti samo imena i adrese e-pošte članova grupe. Ne možete dobiti druge podatke o članovima, poput tvrtke, radnog mjesta, telefonskog broja ili poslovne adrese, itd. Općenito, da biste dobili ove detalje, morate ručno pronaći kontakte koji odgovaraju članovima u vašoj mapi Kontakti. Previše je problematično. Ovdje ćemo vam pokazati dio VBA koda, koji može brzo izvesti te detalje u Excel radnu knjigu.

Izvezite pojedinosti o svim članovima u grupi kontakata u Excel

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim biste trebali pritisnuti tipke prečaca “Alt + F11” u glavnom prozoru programa Outlook.
3. Zatim u novom prozoru “Microsoft Visual Basic for Applications” morate otvoriti modul koji nije u upotrebi ili izravno umetnuti novi modul.
4. Nakon toga kopirajte i zalijepite sljedeći VBA kod u ovaj modul.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Nakon toga, za praktičnu provjeru, možete dodati novi VBA projekt na alatnu traku za brzi pristup ili vrpcu.
6. Kasnije postavite razinu sigurnosti Outlook makroa na nisku.
7. U konačnici, možete pokušati.

• Najprije odaberite grupu kontakata.
• Zatim pritisnite gumb makronaredbe na alatnoj traci za brzi pristup ili na vrpci.
• Odmah će se pokrenuti makronaredba.
• Kada završi, dobit ćete upit "Dovršeno!"
• Nakon toga možete otići u unaprijed definiranu odredišnu lokalnu mapu u kojoj možete pronaći novu Excel datoteku.
• Otvorite ga, vidjet ćete podatke za kontakt članova grupe kao na sljedećoj snimci zaslona:

Nemojte paničariti pred problemima s Outlookom

Nitko nije voljan prihvatiti probleme s Outlookom, bez obzira na skočnu poruku o pogrešci ili pokvareni Outlook podatkovna datoteka. Stoga će korisnici biti skloni panici kada naiđu na probleme s Outlookom. Ako u tom slučaju želite ostati mirni, trebali biste imati pri ruci dvije stvari. Jedan je trenutna sigurnosna kopija Outlook podataka. Drugi je moćan softver za popravak Outlooka, npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql oporavak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com