Kako brzo priložiti određene stranice Word dokumenta Outlook e-pošti

MS Word ima izravnu značajku koja podržava korisnike da pošalju trenutni Word dokument kao privitak e-pošte. Ali ponekad se samo nadate da ćete Outlook e-pošti priložiti određene stranice Word dokumenta. Sada, ovaj članak će vam podijeliti metodu.

Da biste poslali cijeli Word dokument kao privitak e-pošte u aplikaciji MS Word, možete jednostavno otići na izbornik "Datoteka" i prijeći na karticu "Spremi i pošalji", ispod koje možete pronaći gumb "Pošalji kao privitak". Ipak, ponekad ono što želite poslati mogu biti samo određene stranice dokumenta. U ovoj situaciji možete upotrijebiti metodu predstavljenu u nastavku da biste to postigli.

Priložite određene stranice Word dokumenta e-poruci

1. Najprije biste trebali otvoriti izvorni Word dokument čije određene stranice želite poslati e-poštom.
2. Zatim, nakon što uđete u prozor MS Worda, morate pritisnuti tipke "Alt + F11".
3. Zatim ćete dobiti pristup VBA uređivaču u MS Wordu.
4. Nakon toga morate omogućiti "Microsoft Outlook Object Library". To možete postići klikom na "Alati" > "Referenca".
5. Nakon toga trebate kopirati sljedeći VBA kod u modul koji nije u upotrebi.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Konačno, možete pokrenuti ovu makronaredbu. Samo pritisnite tipku F5 ili dodirnite ikonu "Pokreni" na alatnoj traci.
7. Nakon što makronaredba završi, prikazat će se nova Outlook e-pošta, koja je priložena s izvatkom izvornog Word dokumenta, poput sljedeće snimke zaslona:

Izdvojite maksimum podataka iz oštećene Outlook datoteke

Ako ste desetljećima koristili Outlook, možda ste se suočili s raznim problemima s Outlookom, uključujući skočne unutarnje poruke o pogrešci, iznenadna rušenja kao i ozbiljna oštećenja datoteka. Zbog činjenice da je scanpst, ugrađeni alat za popravak, može se nositi samo s malim problemima, bilo bi vam bolje da pri ruci držite vanjski snažni alat za popravak, recimo DataNumen Outlook Repair. Može izvući maksimum podataka iz oštećene podatkovne datoteke programa Outlook.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql popravak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com