Kako brzo priložiti zadnju izmijenjenu datoteku u Windows mapi svojoj Outlook e-pošti

Ponekad ćete možda htjeti brzo pronaći i priložiti posljednju izmijenjenu datoteku u određenoj Windows mapi u Outlook e-poštu. U tom slučaju možete upotrijebiti metodu predstavljenu u ovom članku.

Neki korisnici žele da Outlook brzo pronađe i doda zadnju izmijenjenu datoteku u mapi sustava Windows u e-poštu, poput najnovije stvorene, promijenjene ili spremljene datoteke. Međutim, Outlook ne nudi takvu izravnu i izvornu značajku. Stoga ćemo u nastavku prikazati dio VBA koda koji to može lako ostvariti.

Priložite posljednju izmijenjenu datoteku u Windows mapi e-pošti

1. Na samom početku trebali biste pokrenuti svoju Outlook aplikaciju.
2. Zatim, nakon što uđete u glavni prozor programa Outlook, možete pritisnuti tipke "Alt + F11".
3. Zatim ćete uspješno pristupiti Outlook VBA prozoru uređivača.
4. Nakon toga, trebali biste pronaći i otvoriti modul koji se ne koristi.
5. Zatim kopirajte i zalijepite sljedeći VBA kod u ovaj prozor modula.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Nakon toga možete izaći iz trenutnog prozora uređivača VBA i nastaviti s dodavanjem nove makronaredbe na alatnu traku za brzi pristup ili na vrpcu prozora poruka.
7. Kasnije ćete morati promijeniti razinu sigurnosti Outlook makroa na nisku.
8. Na kraju možete pokušati.

• Najprije stvorite i sastavite novu Outlook e-poštu kao i obično.
• Zatim pritisnite gumb makronaredbe na alatnoj traci za brzi pristup, kao na slici ispod:
• Zatim ćete morati odabrati izvornu Windows mapu i pritisnuti "OK".
• Ako postoji takva datoteka u odabranoj Windows mapi, dobit ćete upit poput sljedeće snimke zaslona:
• Kada pritisnete "Da", ova će datoteka biti priložena odjednom.

Riješite Outlook probleme što je prije moguće

Kad god naiđete na probleme s Outlookom, preporučuje se da ih riješite što je prije moguće. U ovoj situaciji, bolje pripremite robusnu Outlook popravak alat unaprijed, kao što je DataNumen Outlook Repair. Sposoban je popraviti PST pogreške i učinkovito spasiti vaše Outlook podatke.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećeni mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com