Kako postaviti različito zadano vrijeme podsjetnika za različite vrste označenih stavki u vašem Outlooku

Prema zadanim postavkama, Outlook će automatski koristiti zadano vrijeme podsjetnika zadataka za sve vrste označenih stavki. Ipak, ako želite koristiti drugačije vrijeme podsjetnika za označene stavke na temelju vrste stavke, možete se obratiti metodi predstavljenoj u ovom članku.

Outlook vam omogućuje postavljanje zadanog vremena podsjetnika za sve označene stavke, bez obzira na vrstu stavke. Možete otići na izbornik "Datoteka" i kliknuti "Opcije". Zatim, u prozoru "Opcije programa Outlook", možete vidjeti opciju "Zadano vrijeme podsjetnika" na kartici "Zadaci", kao što je prikazano na sljedećoj snimci zaslona.

Ipak, većina korisnika se nada koristiti različita vremena podsjetnika za različite vrste označenih stavki, kao što je „9:00“ za označene e-poruke i „17:30“ za označene kontakte. U nastavku ćemo se usredotočiti na ovaj primjer kako bismo predstavili metodu.

Postavite drugačije zadano vrijeme podsjetnika za različite vrste označenih stavki

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim pristupite uređivaču Outlook VBA s referencom na "Kako pokrenuti VBA kod u vašem Outlooku".
3. U sljedećem prozoru “Microsoft Visual Basic za aplikacije” kopirajte sljedeći kod u projekt “ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Nakon toga ponovno pokrenite Outlook da biste aktivirali ovaj makro.
5. Od sada, svaki put kada označite e-poštu, vrijeme podsjetnika bit će postavljeno na "10:00" na datum dospijeća označavanja.
6. A kada označite kontakt, vrijeme podsjetnika bit će postavljeno na "17:30" na datum dospijeća za označavanje.

Fleksibilno se pozabavite Outlook problemima

U Outlooku možete naići na sve vrste problema. Stoga morate unaprijed naučiti neke mjere za rješavanje problema. Na primjer, ako se vaš Outlook često ponovno pokreće, trebate popraviti Office ili onemogućiti dodatke trećih strana itd. Ili ako je vaš Outlook PST kompromitiran, prvo možete pokušati alat za popravak inboxa. Kada ne uspije, možete nastaviti pribjegavati moćnom vanjskom alatu, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući mdf oporavak i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com