Kako brzo izdvojiti sve primatelje iz više datoteka Outlook poruka (.msg).

Neki korisnici željeli bi brzo izdvojiti sve primatelje iz više datoteka Outlook poruka spremljenih iz Outlook e-pošte. Sada, ova strost pogledat će ovo kako bismo podijelili brz pristup.

Da biste izvukli primatelje iz jedne Outlook datoteke poruke, možete samo dvaput kliknuti da je otvorite, a zatim kopirati primatelje u otvorenom prozoru poruke. No, ako se trebate pozabaviti grupom Outlookovih datoteka poruka, ručna metoda nije dovoljno učinkovita. Stoga možete potražiti mnogo učinkovitiji način. Ovdje ćemo vam predstaviti takav. Čitajte dalje da biste saznali detalje.

Ekstrahirajte sve primatelje iz višestrukih Outlook poruka (.msg) datoteka

1. Za astart, dobiti pristup uređivaču Outlook VBA prema "Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim kopirajte i zalijepite sljedeći VBA kod u prazan modul.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Zatim pomaknite kursor u prvom potprogramu.
4. Nakon toga kliknite gumb "Pokreni" ili pritisnite tipku "F5".
5. Zatim u skočnom dijaloškom okviru odaberite Windows mapu koja sadrži izvorne Outlook poruke (.msg) datoteke.
6. Nakon odabira, kliknite "OK" da biste pustili makronaredbu da nastavi s radom.
7. Kada makronaredba završi, pojavit će se poruka s popisom svih izdvojenih adresa e-pošte primatelja, kao što je prikazano na sljedećoj snimci zaslona.

Zaštitite svoje Outlook podatke od opasnosti

Outlook podaci su skloni korupciji. Stoga je prilično težak zadatak zaštititi Outlook podatke. Zahtijeva da ustrajete u redovitom sigurnosnom kopiranju Outlook podataka. Također, ako je moguće, razborito je i preporučljivo pripremiti iskusan i profesionalan Outlook PST popravak alat, poput DataNumen Outlook Repair, tako da možete dobiti trenutno i pravovremeno spašavanje u slučaju oštećenja Outlooka.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti se Sql Server i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com