Kako učinkovito dodati bilješke u Outlook e-poštu putem VBA i korisničkog obrasca

Ponekad se možete nadati da ćete urediti ili dodati bilješke u svoju e-poštu u programu Outlook. Ovaj članak će vam predstaviti učinkovit način za postizanje ove funkcije.

Od “4 jednostavne metode za umetanje bilješke u vaše Outlook poruke“, možete naučiti umetati bilješke u e-poruke putem izvornih funkcija programa Outlook, kao što je korištenje prilagođenih zastavica, upisivanje bilješke u predmet ili tijelo ili prilaganje postojećih stavki bilješki ovoj e-pošti. Ipak, sve su to samo zaobilazna rješenja. Ovdje ćemo vas naučiti mnogo učinkovitiju metodu. Preko njega ćete moći dodavati bilješke u e-poštu te uređivati ​​ili brisati postojeće bilješke po želji.

Dodajte bilješke Outlook e-pošti

1. Za početak, pristupite VBA editoru pritiskom na “Alt + F11” u programu Outlook.
2. Zatim kliknite “Umetni” > “Korisnički obrazac”.
3. Zatim, u novom korisničkom obrascu, stvorite tekstualni okvir kao na slici ispod.
4. Zatim promijenite "Ime" tekstnog okvira u "txtNotes", kao na snimci zaslona.
5. Nakon toga kreirajte dva naredbena gumba u obrascu.
6. Zatim odaberite "CommandButton 1". Promijenite "Name" u "btnOK" i promijenite "Caption" u "OK".
7. Nakon toga promijenite “Name” za “CommandVutton 2” u “btnCancel” i “Caption” u “Cancel”.
8. Zatim odaberite cijeli korisnički obrazac i promijenite njegov “Name” u “frmAddNote” i “Caption” u “Unesite svoju bilješku”.
9. Nakon toga desnom tipkom miša kliknite "fromAddNote" i odaberite "View Code".
10. Na novom ekranu kopirajte sljedeći kod u njega.

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objNote = Application.CreateItem(olNoteItem)
 
    objNote.Body = strNote
    objNote.Save
    objMail.Attachments.Add objNote
    objMail.Save
    objNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

11. Kasnije stavite donji VBA kod u neiskorišteni modul.

Sub AddNote()
    frmAddNote.Show
End Sub

12. Na kraju idite na "Datoteka" > "Opcije" > "Prilagodi vrpcu" da dodate ovu makronaredbu na vrpcu.
13. Sada možete pokušati. Odaberite e-poštu i kliknite novi gumb "Dodaj bilješku" na vrpci.
14. U skočni dijaloški okvir možete unijeti svoju bilješku i kliknuti "U redu".
15. Odmah će odabranoj e-pošti biti dodana nova bilješka.

Uredite ili izbrišite postojeće bilješke za Outlook e-poštu

Ponekad ćete možda htjeti urediti ili izbrisati postojeće bilješke u e-poruci. Možete slijediti korake u nastavku.

1. Najprije stvorite još jedan korisnički obrazac i nazovite ga "frmEditNote" i promijenite njegov naslov u "Uredite svoju bilješku".
2. Zatim umetnite novi tekstni okvir u obrazac i promijenite njegov "Naziv" u "txtNotes".
3. Zatim dodajte dva naredbena gumba - "U redu" i "Odustani".
4. Nakon toga desnom tipkom miša kliknite “frmEditNote” i odaberite “View Code”.
5. U novu kodnu stranicu “frmEditNote” stavite sljedeći kod.

Private Sub UserForm_Initialize()
    Dim objAttachNote As Outlook.Attachment
    Dim objTempNote As Outlook.NoteItem

    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    Set objMail = objAttachNote.Parent
 
    If Right(objAttachNote.FileName, 3) = "msg" Then
       strTempFolder = Environ("Temp")
       strFilePath = strTempFolder & "\" & objAttachNote.FileName
       objAttachNote.SaveAsFile strFilePath
    End If
 
    Set objTempNote = Session.OpenSharedItem(strFilePath)
    txtNotes.Text = objTempNote.Body

    objTempNote.Close olDiscard
End Sub

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objAttachNote As Outlook.Attachment
    Dim objNewNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objNewNote = Application.CreateItem(olNoteItem)
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    objAttachNote.Delete

    objNewNote.Body = strNote
    objNewNote.Save
    objMail.Attachments.Add objNewNote
    objMail.Save
    objNewNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

6. Nakon toga otvorite modul i kopirajte VBA kod u njega.

Sub EditNote()
    frmEditNote.Show
End Sub

Sub DeleteNotes()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim objMail As Outlook.MailItem
 
    Set objSelectedAttachments = Application.ActiveExplorer.AttachmentSelection
 
    For Each objAttachment In objSelectedAttachments
        If Right(objAttachment.FileName, 3) = "msg" Then
           objAttachment.Delete
        End If
    Next
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    objMail.Save
End Sub

7. Konačno, možete dodati makronaredbe "EditNote" i "DeleteNotes" na vrpcu.
8. Na kraju, nakon što kliknete "OK" i vratite se na glavni prozor, možete pokušati urediti bilješku.

• Odaberite bilješku i kliknite gumb "Uredi bilješku".
• Zatim će se pojaviti novi dijaloški okvir u kojem možete urediti odabranu bilješku.
• Nakon uređivanja kliknite na "OK". Bilješka će se ažurirati.

9. Također, možete pokušati izbrisati sve bilješke.

• Odaberite bilješku koju želite izbrisati.
• Kliknite gumb "Izbriši bilješke" na vrpci.
• Ova bilješka će biti izbrisana odjednom.

Spriječite Outlook od gubitka podataka

Tražite li moćno rješenje za blokiranje gubitka podataka u programu Outlook? Iskreno govoreći, sve dok redovito izrađujete sigurnosne kopije Outlook podataka, možete s lakoćom izbjeći gubitak PST podataka. Na primjer, čak i ako se PST ošteti, to možete lako učiniti oporaviti PST podataka iz sigurnosne kopije PST datoteke kao povjetarac.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti sql i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com