Kako automatski istaknuti važne poruke e-pošte na koje niste odgovorili u programu Outlook

Kako ne biste zaboravili odgovoriti na važne poruke e-pošte, možda želite da Outlook prikaže vitalne poruke e-pošte na koje niste odgovorili u određenoj boji manifesta kako biste ih istaknuli. Sada, ovaj članak će vas naučiti kako ga dobiti.

Jeste li ikada propustili neku važnu e-poštu i niste odgovorili na vrijeme? Ako ste patili od takvih problema, možda ćete se nadati da Outlook može istaknuti važne poruke e-pošte na koje niste odgovorili. U nastavku ćemo vas uputiti kako to postići pomoću VBA. Pod uvjetom da niste upoznati s VBA, pogledajte moj prethodni članak – "Kako pokrenuti VBA kod u vašem Outlooku” u međuvremenu.

Automatski označite važne poruke e-pošte na koje niste odgovorili

1. Na samom početku pristupite VBA editoru preko “Alt + F11” u programu Outlook.
2. Zatim u novom prozoru kopirajte donji kod u projekt “ThisOutlookSession”.

Private WithEvents objSentFolder As Outlook.Folder
Private WithEvents objSentMails As Outlook.Items
Private objInbox As Outlook.Folder

'On startup, auto update the replied status of the emails in Inbox
Private Sub Application_Startup()
    Set objSentFolder = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail)
    Set objSentMails = objSentFolder.Items
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateRepliedStatus(objInbox)
End Sub

'After sending an email, auto update the replied status of the emails in Inbox
Private Sub objSentMails_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       Call UpdateRepliedStatus(objInbox)
    End If
End Sub

Private Sub UpdateRepliedStatus(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objRepliedProperty As Outlook.UserProperty
    Dim strRepliedStatus As String
 
    'Write the replied status to a new user property of emails
    For i = objFolder.Items.Count To 1 Step -1
        If objFolder.Items(i).Class = olMail Then
           Set objMail = objFolder.Items(i)
 
           Set objRepliedProperty = objMail.UserProperties.Find("Replied", True)
           If objRepliedProperty Is Nothing Then
              Set objRepliedProperty = objMail.UserProperties.Add("Replied", olText, True)
           End If
 
           strRepliedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If (Not (strRepliedStatus = 102)) And (Not (strRepliedStatus = 103)) Then
              objRepliedProperty.Value = "No"
           Else
              objRepliedProperty.Value = "Yes"
           End If
 
           objMail.Save
        End If
    Next
End Sub

3. Nakon toga, pomaknite kursor u makro "Application_Startup" i pritisnite "F5".
4. Kasnije zatvorite ovaj prozor.
5. Nakon toga slijedite korake u nastavku da biste stvorili pravilo uvjetnog oblikovanja za stavke u Inboxu.

• Najprije prijeđite na mapu "Inbox".
• Zatim otvorite karticu "Prikaz" i kliknite "Postavke prikaza".
• U novom dijaloškom okviru kliknite gumb "Uvjetno oblikovanje".
• U sljedećem dijaloškom okviru "Uvjetno oblikovanje" kliknite "Dodaj" i unesite naziv za novo pravilo, kao što je "Važne poruke e-pošte bez odgovora".
• Kasnije kliknite gumb "Font..." i postavite stil i boju fonta u skočnom dijaloškom okviru "Font".
• Nakon što navedete font, pritisnite "Uvjet..." u dijaloškom okviru "Uvjetno oblikovanje".
• Nakon toga, na zaslonu "Filtar", na kartici "Napredno", dodajte dva filtra.

1. “Važnost” > “jednako” > “Visoka”
2. “Odgovoreno” > “je (točno)” > “Ne”

• Naposljetku, kliknite niz "U redu" da biste spremili ovo pravilo oblikovanja.

6. Nakon što se vratite u Inbox, sve važne e-poruke na koje niste odgovorili bit će označene određenim fontom i bojom.

Nemojte biti opušteni u Outlook zaštiti podataka

Bezbrojni korisnici i dalje misle da im se nikada neće dogoditi oštećenje podataka. U stvarnosti, takve su ideje potpuno pogrešne i rizične. Većinu vremena, mala pogreška može lako dovesti do gubitka podataka. Na primjer, ako slučajno kliknete na zlonamjernu poveznicu u nepoznatim e-porukama, vaša Outlook datoteka može biti zaražena virusom, pa čak i oštećena. Stoga biste trebali biti oprezni u zaštiti podataka, poput redovitog izrade PST sigurnosnih kopija i pripreme moćnog alata za popravak, poput... DataNumen Outlook Repair, koji može popraviti Outlook problema u tren oka.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com