3 metode za uvoz e-pošte iz Windows mape u Outlook

Možda ste spremili nekoliko Outlookovih poruka e-pošte u svoju Windows mapu. Sada, ako ih želite uvesti natrag u mapu programa Outlook, kako to možete učiniti? Ovaj članak će vas naučiti 3 načina.

Kao što svi znamo, Outlook nudi ugrađenu opciju - "Spremi kao", pomoću koje možete spremiti e-poštu u Windows mapu. Međutim, ne postoji značajka za ponovno dodavanje izvezene e-pošte natrag u mapu programa Outlook. Stoga, ako želite uvesti Outlook e-poštu natrag u Outlook, kako to možete ostvariti? U nastavku ćemo vas naučiti 3 metode. Možete odabrati bilo koju prema svojim željama.

Metoda 1: Povucite i ispustite za uvoz

1. Na samom početku morate pristupiti izvornoj Windows mapi koja pohranjuje Outlook e-poštu za uvoz u Outlook.
2. Zatim pokrenite Outlook aplikaciju.
3. Zatim otvorite Outlook mapu u koju želite uvesti e-poštu.
4. Nakon toga morate suziti i prozor mape Windows i prozor programa Outlook dok ih u međuvremenu ne budete mogli vidjeti.
5. Nakon toga, u mapi Windows, možete odabrati jednu od Outlookovih e-poruka, a zatim pritisnite “Ctrl + A” da ih odaberete sve.
6. Kasnije možete povući i ispustiti odabrane poruke e-pošte u vidljivu Outlook mapu, kao na sljedećoj snimci zaslona:
7. Na kraju ćete vidjeti da su sve poruke e-pošte programa Outlook uvezene iz mape Windows u mapu Outlook, prikazano na slici ispod:

Metoda 2: Koristite "CreateItemFromTemplate" u VBA

1. Za početak, u glavnom prozoru Outlooka pritisnite tipke "Alt + F11".
2. Zatim ćete dobiti pristup Outlook VBA prozoru uređivača.
3. Zatim kopirajte sljedeći VBA kod u prazan modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Zatim možete pritisnuti tipku F5 u trenutnom prozoru modula za pokretanje makroa.
5. Nakon toga trebate potražiti izvornu Windows mapu u skočnom dijaloškom okviru.
6. Na kraju, nakon odabira izvorne mape, sve Outlook stavke u toj mapi bit će uvezene u unaprijed definiranu Outlook mapu.
7. Napomena: na ovaj su način sve uvezene e-poruke nove e-poruke koje možete sastavljati po želji, kao na sljedećoj snimci zaslona:

Metoda 3: Iskoristite "OpenSharedItem" u VBA

1. Kao i Metoda 2, kopirajte sljedeće VBA kodove u drugi modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Zatim pokrenite ovu makronaredbu pritiskom tipke "F5".
3. Zatim odaberite izvornu mapu.
4. Na kraju će sve e-poruke biti uvezene kao na slici ispod:

Usporedbe

Sredstva za blokiranje oštećenja PST podataka

Kao što svi znamo, Outlook dolazi unaprijed instaliran s ugrađenim alatom – scanpstVećinom je sposoban riješiti manje probleme. Međutim, ako su problemi ozbiljni, ugrađeni alat će vjerojatno zakazati. Stoga je bolje da se vratite jačem alatu, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući SQL Server korupcija i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com