2 načina skupnog označavanja svih poruka e-pošte programa Outlook starijih od određenog datuma kao pročitanih

Nakon uvoza više starih e-poruka u Outlook i te e-pošte u statusu "nepročitano", morate ih skupno označiti kao pročitane. Sada ćemo vam u ovom članku pokazati 2 brze metode.

Ponekad ćete možda morati skupno označiti više e-poruka kao pročitane. Na primjer, imate staru PST datoteku koja sadrži mnogo starih e-poruka. Zatim uvezete e-poštu u vlastitu Outlook PST datoteku. Međutim, nakon uvoza te se e-poruke prema zadanim postavkama prikazuju kao "Nepročitane". U ovom trenutku, ove poruke e-pošte, starije od određenog datuma, trebali biste grupno označiti kao pročitane. Ovdje ćemo pogledati ovaj zahtjev kako bismo podijelili 2 praktična i učinkovita pristupa.

Metoda 1: Skupno označavanje pronađenih poruka e-pošte kao pročitanih ručno

1. Za početak, otvorite mapu pošte.
2. Zatim kliknite na okvir za pretraživanje.
3. Zatim na vrpci "Traži" kliknite gumb "Sve stavke pošte" u grupi "Opseg".
4. Nakon toga u okvir za pretraživanje unesite kriterij "poslano: <=2018/5/21". Promijenite "2018/5/12" na željeni datum.
5. Kada je pretraživanje završeno, odaberite sve pronađene pošte pomoću “Ctrl + A”.
6. Na kraju kliknite desnom tipkom miša i odaberite opciju "Označi oglas kao pročitan".

Metoda 2: Skupno označavanje poruka e-pošte starijih od određenog datuma kao pročitanih pomoću VBA

1. Za početak pokrenite VBA editor u Outlooku prema “Kako pokrenuti VBA kod u vašem Outlooku".
2. Zatim kopirajte sljedeći kod u modul.

Dim dDate As Date

Sub MarkEmailsOlderThanSpecificDateRead()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    dDate = InputBox("Enter the specific date:", , "2018/5/11")
 
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
 
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If TypeOf objItem Is MailItem Then
           Set objMail = objItem
 
           If objMail.SentOn <= dDate Then
              If objMail.UnRead = True Then
                 objMail.UnRead = False
                 objMail.Save
              End If
           End If
        End If
    Next
 
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

3. Nakon toga, pritisnite tipku “F5” za pokretanje ove makronaredbe odmah.
4. Kasnije, u malom skočnom dijaloškom okviru, unesite određeni datum i pritisnite "OK".
5. Na kraju će sve e-poruke starije od određenog datuma biti označene kao pročitane.

Vratite ugroženu Outlook datoteku

Outlook PST datoteke mogu se oštetiti nakon što se Outlook tu i tamo neočekivano sruši. Ako imate ažuriranu sigurnosnu kopiju, možete jednostavno oporaviti Outlook podatke sa sigurnosnom kopijom. U suprotnom, nemate drugog izbora nego potražiti specijaliziranog stručnjaka ili uslužni program, kao što je DataNumen Outlook Repair za popravak Outlook datoteke.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući mdf fix i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com