2 metode za brzo slanje odabranih ćelija u Excel radnom listu kao Outlook e-poštu

Ponekad ćete možda htjeti brzo umetnuti odabrane ćelije u Excelovom radnom listu u Outlook e-poštu i poslati ovu e-poruku. Ovaj članak će se osvrnuti na ovu želju i ponuditi vam 2 metode.

Moj prethodni članak "2 brze metode za slanje Excel radnog lista kao Outlook e-pošte” vas je naučio kako poslati cijeli Excel radni list kao e-mail. Međutim, ponekad samo želite poslati odabrane ćelije na radnom listu kao e-poruku. Kao odgovor na ovaj zahtjev, ovdje ćemo vam predstaviti 2 metode. Možete birati prema svojim željama.

1. metoda: Ručno kopirajte odabrane ćelije u e-poštu

1. Za početak, otvorite izvornu Excel datoteku i pristupite odgovarajućem Excel radnom listu.
2. Zatim odaberite ćelije koje želite poslati kao Outlook e-poštu.
3. Zatim pritisnite tipke prečaca "Ctrl + C" za kopiranje odabranih ćelija.
4. Nakon toga pokrenite Outlook aplikaciju.
5. Nakon toga kliknite gumb "Nova e-pošta" na vrpci "Početna" da biste stvorili novu Outlook e-poštu.
6. Kasnije u novom prozoru poruke kliknite na odjeljak tijela poruke.
7. Zatim pritisnite tipke "Ctrl + V" da zalijepite prethodno kopirane odabrane ćelije programa Excel.
8. Na kraju, možete sastaviti e-poštu kao i obično i kliknuti gumb "Pošalji" da biste je poslali.

Metoda 2: Pošaljite odabrane ćelije kao e-poruku putem VBA

1. Na samom početku otvorite izvornu Excel radnu knjigu.
2. Zatim pritisnite tipke "Alt + F11" za pristup Excel VBA uređivaču.
3. U novom prozoru kliknite “Umetni” > “Modul” za umetanje novog modula.
4. Zatim biste trebali omogućiti objekte Microsoft Outlooka. Kliknite "Alati" > "Reference". U skočnom dijaloškom okviru pronađite i označite "Biblioteka objekata Microsoft Outlooka".
5. Nakon toga kopirajte sljedeći VBA kod u ovaj modul.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Naposljetku, možete pokušati.

• Prvo odaberite određene ćelije kao i obično.
• Zatim se vratite na novu makronaredbu i pritisnite tipku F5 da biste je pokrenuli.
• Odmah će se prikazati nova Outlook e-pošta u kojoj možete vidjeti da su odabrane ćelije umetnute u tijelo e-pošte, kao na sljedećoj snimci zaslona:

PST datoteka jednako je ranjiva kao Excel datoteka

Kao što znamo, Excel datoteke i Word dokumenti skloni su oštećenju. Zapravo, isto vrijedi i za PST datoteku, koja sadrži sve stavke u vašem Outlook poštanskom sandučiću. Dakle, zaštita vaših PST podataka je težak zadatak. Jedna od najučinkovitijih mjera je redovito stvaranje sigurnosnih kopija datoteke. Osim toga, kako biste osigurali trenutno spašavanje, bolje je da pripremite iskusan alat, kao što je DataNumen Outlook Repair, koji je u mogućnosti oporaviti Outlook podataka bez da se oznojite.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popravak mdf-a i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com