Comment trouver rapidement des paragraphes d'une phrase dans votre document Word

Dans cet article, nous souhaitons vous montrer comment trouver rapidement tous les paragraphes d'une seule phrase dans votre document Word via VBA.

De temps en temps, certains documents peuvent avoir des exigences très spécifiques pour leur formatage et leurs structures. Par exemple, vous ne pouvez pas être autorisé à avoir des paragraphes avec une seule phrase. Ces paragraphes ne sont pas difficiles à reconnaître, mais cela prend du temps, surtout que c'est un long document.

Aujourd'hui, nous vous proposons le moyen rapide de spécifier tous les paragraphes d'une phrase dans votre document.

Trouver tous les paragraphes d'une phrase dans un seul document

1. Premièrement, Word compte un point comme une phrase. Donc, s'il y a des mots tels que "M." ou "Ms.", Word le considère comme une phrase. Pour exclure une telle distraction, vous devez remplacer "M." avec "Monsieur". Et lorsque vous avez terminé de trouver un paragraphe d'une seule phrase, vous pouvez les modifier. Pour remplacer des mots, vous pouvez vous référer à ce lien : Comment rechercher et remplacer plusieurs éléments dans votre document Word
2. Deuxièmement, appuyez sur "Alt + F11" pour déclencher l'éditeur VBA.
3. Cliquez ensuite sur le projet "Normal".
4. Cliquez sur l'onglet "Insérer" dans la barre de menu et choisissez "Module" dans son menu déroulant.
5. Double-cliquez ensuite sur le module pour l'ouvrir.
6. Collez les codes suivants sur le module :

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Enfin, cliquez sur le bouton "Exécuter" ou appuyez sur "F5".

Vous recevrez une telle boîte de message, vous indiquant que le travail est terminé.

Rechercher tous les paragraphes d'une phrase dans plusieurs documents

1. Pour commencer, vous devez placer tous les documents cibles dans un dossier.
2. Ensuite, installez et exécutez la macro ci-dessous :

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Dans la fenêtre "Parcourir" ouverte, choisissez le dossier dans lequel vous conservez les documents et cliquez sur "OK".

La macro mettra alors en surbrillance tous les paragraphes d'une phrase et laissera les documents ouverts. Si un document ne contient pas de paragraphe d'une phrase, il sera fermé. De plus, il y a une boîte de message, indiquant le nombre de paragraphes d'une phrase dans chaque document.

Traiter un incident de perte de données

Les erreurs de l'utilisateur et une panne de courant soudaine peuvent entraîner la mort de Word. Alors qu'un mot effondré peut non seulement affecter le travail quotidien, mais aussi conduire à doc dommageCe n'est de loin pas l'aspect le plus irritant d'une perte de données. Il est préférable d'utiliser un logiciel de réparation pour récupérer les données immédiatement.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupérer Excel et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com