Comment exclure rapidement les destinataires « CC » d'origine lors de l'utilisation de « Répondre à tous » dans Outlook

Lorsque vous utilisez "Répondre à tous", l'e-mail de réponse inclura également les destinataires "CC" de l'e-mail d'origine dans le champ "CC". Mais, si vous souhaitez exclure ce type de destinataire, vous pouvez utiliser la méthode présentée dans cet article.

Parfois, vous souhaitez répondre à un e-mail à l'expéditeur d'origine et aux destinataires "À". Dans ce scénario, vous penserez certainement à utiliser l'option "Répondre à tous". Cependant, par ce moyen, si le courrier d'origine a également des destinataires "CC", l'e-mail "Répondre à tous" copiera automatiquement les destinataires "CC" dans le champ "CC". Si vous ne souhaitez pas y répondre, vous devez les supprimer manuellement, ce qui est un peu gênant. Maintenant, dans ce qui suit, nous vous apprendrons comment laisser Outlook l'accomplir automatiquement selon vos besoins.

Exclure rapidement les destinataires « CC » d'origine lors de l'utilisation de « Répondre à tous »

1. Pour commencer, ouvrez Outlook.
2. Ensuite, accédez à l'éditeur VBA en lisant l'article précédent - "Comment exécuter le code VBA dans votre Outlook" .
3. Ensuite, copiez le code VBA suivant dans le projet "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Ensuite, redémarrez Outlook pour activer ce nouveau projet.
5. Depuis lors, chaque fois que vous cliquez sur le bouton "Répondre à tous", vous obtenez une invite, comme illustré dans l'image suivante, vous demandant si vous souhaitez exclure les destinataires CC d'origine.
6. Si vous sélectionnez "Oui", Outlook supprimera automatiquement les destinataires dans le champ "CC".

Restez bien préparé pour les dommages d'Outlook

Comme chacun sait, personne n'est à l'abri des dommages causés à Outlook. Il est donc essentiel pour tous les utilisateurs réguliers d'Outlook de prendre de nombreuses précautions. Tout d'abord, il est primordial de conserver une sauvegarde régulière et à jour de vos données Outlook. Ensuite, il est nécessaire d'apprendre à utiliser l'outil de réparation de la boîte de réception. Enfin, il est judicieux et recommandé de faire appel à un technicien expérimenté. Correctif Outlook outil à proximité, comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupérer mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com